Refresh thumbnails of folder shortcuts (.lnk)

RefreshShortcuts.vbs

'Refreshes the thumbnails of folder shortcuts (.lnk) files
'Written by Ramesh Srinivasan for winhelponline.com
'Created on 30-05-2024

Option Explicit
Dim WshShell, WshShortcut, FSO
Dim sTarget, sDesc, sSrcFldr, sOut, i
Dim objFolder, colFiles, objFile
Set FSO = CreateObject("Scripting.FileSystemObject")
Set WshShell = CreateObject ("WScript.Shell")

If WScript.Arguments.Count = 0 Then
   sSrcFldr = WshShell.SpecialFolders("Desktop")
   Call RefreshShortcuts
Else
   For i = 0 To WScript.Arguments.Count - 1
      sSrcFldr = WScript.Arguments(i)
      Call RefreshShortcuts
   Next
End If

Sub RefreshShortcuts
   Set objFolder = FSO.GetFolder(sSrcFldr)
   Set colFiles = objFolder.Files
   'Iterate through each .lnk file
   For Each objFile In colFiles
      If LCase(Right(objFile.Name, 4)) = ".lnk" Then
         'Get shortcut properties
         Set WshShortcut = WshShell.CreateShortcut(objFile)
         sTarget = WshShortcut.TargetPath
         sDesc = WshShortcut.Description
         If (FSO.FolderExists(sTarget)) Then	
            WshShortcut.Description = sDesc
            On Error Resume Next
            WshShortcut.Save
            On Error GoTo 0
         End If
      End If
   Next
End Sub

Set WshShell = Nothing
Set FSO = Nothing