gist:7523912

## gistfile1.txt
# Maintainer: Fernando Pacheco <fernando.pacheco@ingesur.com.uy>

pkgname=mingw-w64-uriparser
pkgver=0.7.8
pkgrel=1
arch=('any')
pkgdesc="MinGW Windows port of uriparser library (mingw-w64)"
depends=('mingw-w64-crt')
makedepends=('mingw-w64-gcc')
options=(!strip !buildflags staticlibs)
license=('BSD')
url="http://uriparser.sourceforge.net/"
source=("http://downloads.sourceforge.net/project/uriparser/Sources/${pkgver}/uriparser-${pkgver}.tar.bz2")
md5sums=('1ff590e25e8d9f5eaaa409c741fc387b')

_architectures="i686-w64-mingw32 x86_64-w64-mingw32"

prepare () {
  cd "${srcdir}/uriparser-${pkgver}"
  echo "liburiparser_la_LDFLAGS += -no-undefined" >> Makefile.am
  autoreconf -vfi
}

build()
{
  cd "${srcdir}/uriparser-${pkgver}"
  for _arch in ${_architectures}; do
    unset LDFLAGS
    mkdir -p build-${_arch} && pushd build-${_arch}
    ../configure \
      --host=${_arch} \
      --prefix=/usr/${_arch} \
      --enable-shared \
      --disable-test \
      --disable-doc
    make
    popd
  done
}

package() {
  for _arch in ${_architectures}; do
    cd "${srcdir}/uriparser-${pkgver}/build-${_arch}"
    make DESTDIR="${pkgdir}" install
    ${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
    ${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
  done
}