notmuch-config.el

(defvar cl/message-pandoc-command
  (concat
   "pandoc --smart --template=email -r markdown_github -w html5"
   " | premailer --remove-classes"))

(defun cl/message-multipart-pandoc-preview ()
  "Preview message buffer rendered with pandoc and web browser."
  (interactive)
  (save-excursion
    (message-goto-body)
    (let* ((start (point))
           (default-directory temporary-file-directory)
           (tmp-buff "*pandoc-preview*"))
      (save-window-excursion
        (cl/mml-next-part)
        (shell-command-on-region start (point) cl/message-pandoc-command
                                 tmp-buff)
        (browse-url-of-buffer tmp-buff)))
    (message "Message preview now available in browser.")))

(defun cl/message-multipart-pandoc ()
  "Use pandoc to format a multipart/alternative message."
  (interactive)
  (save-excursion
    (message-goto-body)
    (let* ((start (point)) last-command end)
      (cl/mml-next-part)
      (kill-region start (point))
      (goto-char start)
      (insert "<#multipart type=alternative>\n")
      (yank)
      (insert "<#part type=text/html charset=utf-8>\n")
      (setq start (point))
      (yank)
      (setq end (point))
      (insert "\n<#/multipart>\n")
      (unless
          (= 0 (shell-command-on-region
                start end cl/message-pandoc-command t t))
        (error "pandoc returned error")))))