queryDsl generate by gradle

build.gradle

apply plugin: 'spring-boot'


jar {
    baseName = 'core'
    version = '0.5.0'
}

sourceSets {
    generated {
        java {
            srcDirs = ['src/main/generated']
        }
    }
}

configurations {
    provided
}

dependencyManagement {
    imports {
        mavenBom 'org.springframework.data:spring-data-releasetrain:Gosling-SR1'
    }
}

dependencies {
    def querydslVersion = '3.7.0'
    compile("org.springframework.boot:spring-boot-starter-data-rest")
    compile("org.springframework.boot:spring-boot-starter-data-jpa")
    compile('com.mysema.querydsl:querydsl-jpa:3.7.0')
    compile('com.mysema.querydsl:querydsl-apt:3.7.0')
    provided "com.mysema.querydsl:querydsl-apt:3.7.0"

    testCompile("com.h2database:h2")
    compile('com.oracle:ojdbc14:10.2.0.4.0')
}

task generateQueryDSL(type: JavaCompile, group: 'build', description: 'Generates the QueryDSL query types') {
    source = sourceSets.main.java
    classpath = configurations.compile + configurations.provided
    options.compilerArgs = [
            "-proc:only",
            "-processor", "com.mysema.query.apt.jpa.JPAAnnotationProcessor"
    ]
    destinationDir = sourceSets.generated.java.srcDirs.iterator().next()
}

compileJava {
    dependsOn generateQueryDSL
    source generateQueryDSL.destinationDir
}

compileGeneratedJava {
    dependsOn generateQueryDSL
    options.warnings = false
    classpath += sourceSets.main.runtimeClasspath
}

clean {
    delete sourceSets.generated.java.srcDirs
}

idea {
    module {
        sourceDirs += file('src/main/generated')
    }
}