GroovyでGitコマンド。今のところinit/clone/statusがそれとなく使える。使用例: groovy git clone git@github.com:jenkinsci/mongodb-plugin.git

git.groovy

@Grab('com.madgag:org.eclipse.jgit:1.0.99.0.7-UNOFFICIAL-ROBERTO-RELEASE')
import org.eclipse.jgit.api.*

if (!args) System.exit(0)

def params = [*args]
def commands = [
    init: {
        def cli = new CliBuilder()
        cli._ longOpt: 'bare', 'bare'
        def opt = cli.parse(params)
        Git.init().setDirectory(new File(opt.arguments() ? opt.arguments()[0] : '.')).setBare(opt.b).call()
    },
    clone: {
        def cli = new CliBuilder()
        cli.with {
            _ longOpt:'bare', 'bare'
            b longOpt:'branch', 'branch'
            n longOpt:'no-checkout', 'no-checkout'
        }
        def opt = cli.parse(params)
        def (uri, dir) = opt.arguments()
        if (!uri) {
            cli.usage()
            System.exit(1)
        }
        def cmd = Git.cloneRepository().setURI(uri).setBare(opt.bare).setNoCheckout(opt['no-checkout'])
        if (opt.b) cmd.branch = opt.b
        cmd.directory = new File(dir?:((uri =~ /.*\/(.*)?/)[0][1] - '.git'))
        cmd.call()
    },
    status: {
        Git.open(new File('.')).status().call().with { status ->
            ['added', 'changed', 'removed', 'missing', 'modified', 'untracked'].each { name ->
                status[name].each { println "$name: $it"}
            }
        }
    }
]

(commands[params.remove(0)]?:{println 'no such command.'})()