ANTLRのtree grammarでΣ演算

Calculator.g

grammar Calculator;

options {
  output = AST;
  ASTLabelType=CommonTree;
}

tokens { SUM; NEG; VARIABLE; }	

@members { CommonTree subExpr; }

prog:    sumExpr
    ;
    
sumExpr
	:	'sum' 'i' ':' INT '..' INT 'of' expr -> ^(SUM INT INT expr)
	;
	finally { subExpr = $sumExpr.tree; }
	
expr:    multExpr (('+'^ |'-'^) multExpr)*
    ;
    
multExpr :    unary (('*'^ |'/'^) unary)*
    ;
    
unary	:	factor
	|	'+' factor -> factor	 
	|	'-' factor -> ^(NEG factor)
	;
    
factor	:	DOUBLE
	|	INT
	|	'i' -> VARIABLE
	|	'('! expr ')'!
	;

INT :    '0'..'9'+ ;
DOUBLE 	:	INT '.' INT*
	|	'.' INT
	;

COMMENT
    :   '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;}
    |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
    ;

WS  :    (' '|'\t'|'\n'|'\r')+ {$channel=HIDDEN;} ;

Eval.g

tree grammar Eval;

options {
  tokenVocab=Calculator;
  ASTLabelType=CommonTree;
}

@members {
    int variable;
    
    CommonTree subExpr;
    
    public Eval(CommonTreeNodeStream input,CommonTree tree) {
        this(input);
        this.subExpr = tree;
    }
    
    private Eval(CommonTree tree, int variable){
        this(new CommonTreeNodeStream(tree),tree);
        this.variable = variable;
    }
}

prog:	sumExpr { System.out.println($sumExpr.value); }
    ;
    
sumExpr returns [double value]
    :    ^(SUM
         init=INT { int initialize = Integer.parseInt($init.text); }
         max=INT
             {
              int maximum = Integer.parseInt($max.text);
              variable = initialize;
             }
         c=expr
             {
              $value += c;
              for(int i = variable + 1; i <= maximum; ++i) {
                  Eval eval = new Eval((CommonTree)subExpr.getChild(2),i);
                  value += eval.expr();
              }
             }
         )
    ;
    
expr returns [double value]
    :    ^('+' left=expr right=expr) {$value = left + right;}
    |    ^('-' left=expr right=expr) {$value = left - right;}
    |    ^('*' left=expr right=expr) {$value = left * right;}
    |    ^('/' left=expr right=expr) {$value = left / right;}
    |    ^(NEG result=expr) {$value = -result;}
    |    VARIABLE {$value = variable;}
    |    INT {$value = Integer.parseInt($INT.text);}
    |    DOUBLE {$value = Double.parseDouble($DOUBLE.text);}
    ;