http://stackoverflow.com/questions/9660085/python-permutations-with-constraints

next_permutation.pyx

#file: next_permutation.pyx
from libcpp cimport bool

cimport numpy as np

ctypedef np.int_t dtype_t

cdef extern from "<algorithm>" namespace "std":
    bool cpp_next_permutation "std::next_permutation" (dtype_t* first, dtype_t* last)

def next_permutation(np.ndarray[dtype_t,ndim=1] a):
    cdef dtype_t* first = <dtype_t *>a.data
    return cpp_next_permutation(first, first + a.shape[0])

next_permutation.pyxbld

#file: next_permutation.pyxbld
from distutils.extension import Extension

def make_ext(modname, pyxfilename):
    return Extension(name=modname,
                     sources=[pyxfilename],
		     language="c++")

test_next_permutation.py

#file: test_next_permutation.py
import numpy as np

import pyximport; pyximport.install()
from next_permutation import next_permutation

# see http://stackoverflow.com/a/9660395
groups = [(1,2),(3,4,5),(6,7)]
groupdxs = [i for i, group in enumerate(groups) for j in range(len(group))]
a = np.ascontiguousarray(groupdxs, dtype=np.int)
while True:
    iters = [iter(group) for group in groups]
    print [next(iters[i]) for i in a]
    if not next_permutation(a):
        break