My first attempt at Clojure. Suggestions/criticism welcome.

calculate_change.clj

(let [currency-values [[:hundreds 10000]
                       [:fifties 5000]
                       [:twenties 2000]
                       [:tens 1000]
                       [:fives 500]
                       [:ones 100]
                       [:quarters 25]
                       [:dimes 10]
                       [:nickels 5]
                       [:pennies 1]]]
  (defn calculate-change [paid cost]
    (loop [coins [], remaining (- cost paid), denoms currency-values]
      (if-let [[[coin value] & denoms] (seq denoms)]
        (let [num-coins (quot remaining value)]
          (if (zero? num-coins)
            (recur coins remaining denoms)
            (recur (conj coins [num-coins coin])
                   (- remaining (* num-coins value))
                   denoms)))
        coins)))

  ;; ...or...
  (defn calculate-change [paid cost]
    (remove (comp #{0} first)
            (map :coins
                 (rest
                  (reductions (fn [{:keys [remaining]} [denom value]]
                                (let [num-coins (quot remaining value)]
                                  {:remaining (- remaining (* num-coins value))
                                   :coins [num-coins denom]}))
                              {:remaining (- cost paid)}
                              currency-values))))))