Extract Looney Toons links

looney_toons.pl

#!/usr/local/perls/perl-5.14.2/bin/perl
use v5.14;

use Mojo::UserAgent;

my $ua = Mojo::UserAgent->new;

my $url = 'http://www.toonarific.com/show_episodes.php?show_id=2177';
my @seasons = $ua->get( $url )
	->res
	->dom
	->find( 'select > option' )
	->grep( sub { $_->{value} =~ m/&season=([0-9]+)&/ } )
	->map( sub {
		my( $season ) = $_->{value} =~ m/&season=([0-9]+)&/;
		{
		id => $season,
		year => $_->text,
		}
		}
		)
	->each;
	
my @grand_links;
foreach my $season ( @seasons ) {
	state $url_format = 'http://www.toonarific.com/show_episodes.php?show_id=2177&season=%s&show_rank=-1';
	my $url = sprintf $url_format, $season->{id};
	my $tx = $ua->get( $url );
		
	my @links = $tx->res
		->dom
		->find( 'a' )
		->grep( sub { $_->{href} =~ /episode_id=[0-9]+/ } )
		->map( sub {
			my( $episode ) = $_->{href} =~ /episode_id=([0-9]+)/;
			my( $text ) = $_->text;
			$text =~ s/\s+/ /g;
				{ 
				year    => $season->{year},
				season  => $season->{id}, 
				episode => $episode, 
				href    => $_->{href}, 
				title   => $text
				} 
			} 
			)
		->each
		;

	push @grand_links, @links;
	}

my @keys = qw( season episode title year href );
say join "\t", @keys;

foreach my $link ( @grand_links ) {
	say join "\t", @{ $link }{ @keys };
	}