なんとか見れる形になったvimrc

.vimrc

" *************************************************
" NeoBundle
" *************************************************
if filereadable(expand('~/.vimrc.neobundle'))
  source ~/.vimrc.neobundle
endif

" *************************************************
" NERDTree 
" *************************************************
if filereadable(expand('~/.vimrc.nerdtree'))
  source ~/.vimrc.nerdtree
endif

" *************************************************
" settings
" *************************************************
set tabstop=2
set shiftwidth=2
set autoindent
set nobackup
set imdisable
autocmd Filetype * set formatoptions-=ro

" *************************************************
" key mapping
" *************************************************
"<F4> unite: バッファ一覧 On/Off
nnoremap <silent> <F4> :<C-u>Unite -toggle buffer<CR>
"<F5> NERDTree: On/Off
nnoremap <silent> <F5> :<C-u>:call ExecuteNERDTree()<CR>
"eregex: PECL正規表現
nnoremap / :M/
nnoremap ? :M?
nnoremap ,/ /
nnoremap ,? ?
"cake
nnoremap <Space>cc :Ccontroller
nnoremap <Space>cm :Cmodel
nnoremap <Space>cv :Cview
nnoremap <Space>co :Ccomponent
nnoremap <Space>ce :Celement
nnoremap <Space>ch :Chelper

.vimrc.neobundle

" *************************************************
" NeoBundle
" *************************************************
" NeoBundle がインストールされていない時、
" もしくは、プラグインの初期化に失敗した時の処理
function! s:WithoutBundles()
  colorscheme desert
  " その他の処理
endfunction

" NeoBundle よるプラグインのロードと各プラグインの初期化
function! s:LoadBundles()
  NeoBundle 'tpope/vim-surround'
  NeoBundle 'violetyk/cake.vim'
  NeoBundle 'scrooloose/nerdtree'
  NeoBundle 'Shougo/unite.vim'
  NeoBundle 'othree/eregex.vim'
endfunction

" NeoBundle がインストールされているなら LoadBundles() を呼び出す
" そうでないなら WithoutBundles() を呼び出す
function! s:InitNeoBundle()
  if isdirectory(expand("~/.vim/bundle/neobundle.vim/"))
    filetype plugin indent off
    if has('vim_starting')
      set runtimepath+=~/.vim/bundle/neobundle.vim/
    endif
    try
      call neobundle#rc(expand('~/.vim/bundle/'))
      call s:LoadBundles()
    catch
      call s:WithoutBundles()
    endtry  
  else
    call s:WithoutBundles()
  endif

  filetype indent plugin on
  syntax on
endfunction

call s:InitNeoBundle()

.vimrc.nerdtree

" NERDTree options
let NERDTreeShowHidden = 1

"************************************************************
" 関数：ExecuteNERDTree
" 引用元：http://kokukuma.blogspot.jp/2012/03/vim-nerdtree.html
"************************************************************

" 引数なしで実行したとき、NERDTreeを実行する
"let file_name = expand("%:p")
"if has('vim_starting') &&  file_name == ""
" autocmd VimEnter * call ExecuteNERDTree()
"endif
  
" NERDTreeを表示非表示化する
function! ExecuteNERDTree()
  "b:nerdstatus = 1 : NERDTree 表示中
  "b:nerdstatus = 2 : NERDTree 非表示中
  if !exists('g:nerdstatus')
    execute 'NERDTree ./'
    let g:windowWidth = winwidth(winnr())
    let g:nerdtreebuf = bufnr('')
    let g:nerdstatus = 1 
  elseif g:nerdstatus == 1 
    execute 'wincmd t'
    execute 'vertical resize' 0 
    execute 'wincmd p'
    let g:nerdstatus = 2 
  elseif g:nerdstatus == 2 
    execute 'wincmd t'
    execute 'vertical resize' g:windowWidth
    let g:nerdstatus = 1 
  endif
endfunction