Demonstrate conversion from standard Yesod to yesod-pure

fib.hs

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings     #-}
{-# LANGUAGE TypeFamilies          #-}
import           Control.Applicative         ((<|>))
import           Text.Blaze.Html             (toValue, (!))
import qualified Text.Blaze.Html5            as H
import qualified Text.Blaze.Html5.Attributes as HA
import           Yesod.Pure.NoRoute

instance Yesod App
type Handler = GHandler App App

fibR :: Int -> Route App
fibR i = AppRoute ["fib", toPathPiece i]

getHomeR :: Handler RepHtml
getHomeR = defaultLayout $ do
    setTitle "Hello World!"
    toWidget $ \render -> do
        H.p "Hello World"
        H.a ! HA.href (toValue $ render (fibR 5) []) $ "Fifth fib"
    addCSS "p { color: red }"

getFibR :: Int -> Handler RepHtml
getFibR i = defaultLayout $ do
    setTitle "Fibs"
    toWidget $ \render -> do
        H.p $ do
            "Fib for "
            toHtml i
            ": "
            toHtml $ fibs !! i
        H.a ! HA.href (toValue $ render (fibR $ i + 1) []) $ "Next fib"

fib :: Int -> Int
fib i = fibs !! i

fibs :: [Int]
fibs = 0 : 1 : zipWith (+) fibs (tail fibs)

main :: IO ()
main = warpDebug 3000 $ App $
    method "GET" (serve getHomeR)
    <|> static "fib" (dynamic $ \i -> method "GET" $ serve $ getFibR i)