Less Flimsy Arduino Ocelli

less_flimsy_arduino_ocelli.ino

/*
  Less Flimsy Arduino Ocelli
  
  Get the direction of the source of light from three photoresistors.
  
  Andrej Primc <aprimc@gmail.com> (http://fgh.si)
  
*/


int getSource(int a, int b, int c, int bins = 24) {
  int ab = abs(a - b);
  int bc = abs(b - c);
  int ca = abs(c - a);
  int mul = bins / 6;
  int h;
  int m;
  
  if (a > b && b >= c) {
    h = 0;
    m = mul * 2 * bc / (ca + bc);
  } else if (b >= a && a > c) {
    h = 1;
    m = mul * 2 * ab / (bc + ab);
  } else if (b > c && c >= a) {
    h = 2;
    m = mul * 2 * ca / (ab + ca);
  } else if (c >= b && b > a) {
    h = 3;
    m = mul * 2 * bc / (ca + bc);
  } else if (c > a && a >= b) {
    h = 4;
    m = mul * 2 * ab / (bc + ab);
  } else if (a >= c && c > b) {
    h = 5;
    m = mul * 2 * ca / (ab + ca);
  } else {
    h = 0;
    m = 0;
  }
  return h * mul + m;
}


void setup() {
  Serial.begin(9600);
}


void loop() {
  int a, b, c, h;
  a = analogRead(A0);
  b = analogRead(A1);
  c = analogRead(A2);
  h = getSource(a, b, c);
  
  Serial.print(h);
  Serial.println("");
  
  delay(1000);
}