GLSL shader used for my 3dprint / pico projection mapping experiment test02

facette.frag

//
// Description : Array and textureless GLSL 2D/3D/4D simplex
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : ijm
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//

vec3 mod289(vec3 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }
vec4 mod289(vec4 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }
vec4 permute(vec4 x) { return mod289(((x*34.0)+1.0)*x); }
vec4 taylorInvSqrt(vec4 r){ return 1.79284291400159 - 0.85373472095314 * r; }

float snoise(vec3 v){
    const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
    const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);
    vec3 i  = floor(v + dot(v, C.yyy) );
    vec3 x0 =   v - i + dot(i, C.xxx) ;
    vec3 g = step(x0.yzx, x0.xyz);
    vec3 l = 1.0 - g;
    vec3 i1 = min( g.xyz, l.zxy );
    vec3 i2 = max( g.xyz, l.zxy );
    vec3 x1 = x0 - i1 + C.xxx;
    vec3 x2 = x0 - i2 + C.yyy;
    vec3 x3 = x0 - D.yyy;
    i = mod289(i);
    vec4 p = permute( permute( permute( i.z + vec4(0.0, i1.z, i2.z, 1.0 )) + i.y + vec4(0.0, i1.y, i2.y, 1.0 )) + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));
    float n_ = 0.142857142857; // 1.0/7.0
    vec3  ns = n_ * D.wyz - D.xzx;
    vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
    vec4 x_ = floor(j * ns.z);
    vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)
    vec4 x = x_ *ns.x + ns.yyyy;
    vec4 y = y_ *ns.x + ns.yyyy;
    vec4 h = 1.0 - abs(x) - abs(y);
    vec4 b0 = vec4( x.xy, y.xy );
    vec4 b1 = vec4( x.zw, y.zw );
    vec4 s0 = floor(b0)*2.0 + 1.0;
    vec4 s1 = floor(b1)*2.0 + 1.0;
    vec4 sh = -step(h, vec4(0.0));
    vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
    vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;
    vec3 p0 = vec3(a0.xy,h.x);
    vec3 p1 = vec3(a0.zw,h.y);
    vec3 p2 = vec3(a1.xy,h.z);
    vec3 p3 = vec3(a1.zw,h.w);
    vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
    p0 *= norm.x;
    p1 *= norm.y;
    p2 *= norm.z;
    p3 *= norm.w;
    vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
    m = m * m;
    return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1), 
                                 dot(p2,x2), dot(p3,x3) ) );
}


//------------------------------------------------------------

//
// Description : Flat shading smooth animation of faces
//      Author : Cyril Diagne - @kikko_fr
//

uniform float time;
uniform vec3 color;
uniform float mult;
uniform float offset;
varying vec3 ec_pos;

float rand(vec2 co){
    return fract(sin(dot(co.xy ,vec2(12.9898,78.233))) * 43758.5453);
}

const vec4 on = vec4(0.5, 0.5, 1.0, 1.0);
const vec4 off = vec4(vec3(0.), 1.);

void main() {
    
    // face normal in eyespace:
    vec3 ec_normal = normalize(cross(dFdx(ec_pos), dFdy(ec_pos)));
    vec3 xyz = ec_normal.xyz;
    float t = time*0.5;
    // Six components of noise in a fractal sum
    float n = snoise(xyz - vec3(0.0, 0.0, t));
    n += 0.5 * snoise(xyz * 2.0 - vec3(0.0, 0.0, t*1.4));
    n += 0.25 * snoise(xyz * 4.0 - vec3(0.0, 0.0, t*2.0));
    n += 0.125 * snoise(xyz * 8.0 - vec3(0.0, 0.0, t*2.8));
    n += 0.0625 * snoise(xyz * 16.0 - vec3(0.0, 0.0, t*4.0));
    n += 0.03125 * snoise(xyz * 32.0 - vec3(0.0, 0.0, t*5.6));
    
    gl_FragColor = vec4( color + vec3(n, n, n) * mult + offset, 1.0);
}

facette.vert

varying vec3 ec_pos;

void main() {

	gl_Position = gl_ModelViewProjectionMatrix * gl_Vertex;
    ec_pos = (gl_ModelViewMatrix * gl_Vertex).xyz;
}