GZip.pm

package Mojolicious::Plugin::GZip;
use Mojo::Base 'Mojolicious::Plugin';

use IO::Compress::Gzip 'gzip';

# Just set "gzip => 1" in the stash and it will try to compress your content
sub register {
  my ($self, $app) = @_;
  $app->hook(
    after_dispatch => sub {
      my $self = shift;

      # Check if GZip compression is desirable
      return unless $self->stash->{gzip};
      return unless ($self->req->headers->accept_encoding // '') =~ /gzip/i;
      my $res   = $self->res;
      my $asset = $res->content->asset;
      return if $asset->is_file     || !$asset->size;
      return if $asset->start_range || $asset->end_range;

      # Compress content
      gzip \(my $dummy = $asset->slurp), \my $compressed;
      $res->body($compressed);
      $res->headers->content_encoding('gzip');
    }
  );
}

1;

Bad for big files, because both, original and compressed file are loaded into RAM.

oh, didn't spot the
return unless !$asset->is_file
so it's probably only for small files anyway

nm

...much better... ;-)