WIP for github.com/gregbell/active_admin/issues/1815

batch_actions.js.coffee

$ ->
  confirmBox = (message, inputs, callback) ->
    html = """<div id="dialog_confirm" title="Confirmation"><p>#{message}</p>""" +
      inputs.map((a)-> """<label>#{a}</label><input name="#{a}"></input>""").join("\n") +
      "</div>"
    $(html).appendTo('body').dialog
      modal: true
      buttons:
        OK: ->
          callback $(@).find('input').serializeArray()
          $(@).dialog('close')
        Cancel: ->
          $(@).dialog('close').remove()

  $('#batch_actions_selector li a').click (event)->
    if message = $(@).data 'confirm'
      confirmBox message, $(@).data('inputs'), (inputs)=>
        $(@).trigger 'confirm:complete', inputs
    else
      $(@).trigger 'confirm:complete'
    event.stopPropagation() # prevent Rails UJS click event

  $('#batch_actions_selector li a').on 'confirm:complete', (event, inputs)->
    $('#batch_action_inputs').val JSON.stringify inputs
    $('#batch_action').val $(@).data('action')
    $("#collection_selection").submit()