A GroovyFX version of the Canoo JavaFX Abacus tutorial part iii

abacus.groovy

@Grab('org.codehaus.groovyfx:groovyfx:0.3.1')
import static groovyx.javafx.GroovyFX.start
 
final int ROW_COUNT = 10
final int COL_COUNT = 10
final int RADIUS    = 20
final int DIAMETER  = 2 * RADIUS
final int WIDTH     = COL_COUNT * DIAMETER
final int HEIGHT    = ROW_COUNT * DIAMETER
final int MOVE_WAY  = 100
 
start {
  stage( title: 'GroovyFX Abacus', visible: true ) {
    scene( width: WIDTH + MOVE_WAY, height: HEIGHT ) {
      (0..<ROW_COUNT).each { int row ->
        (0..<COL_COUNT).each { int column ->
          circle( radius : RADIUS - 1,
                  centerX: RADIUS + ( column * DIAMETER ),
                  centerY: RADIUS + ( row * DIAMETER ),
                  onMouseClicked: { e ->
                    int newX = e.source.translateX > 1 ? 0 : MOVE_WAY
                    translateTransition( 200.ms, node:e.source, toX:newX ).playFromStart()
                  } )
        }
      }
    }
  }
}

Original JavaFX tutorial here http://www.canoo.com/blog/2013/01/21/javafx-abacus-tutorial-part-iii/

added a back link. Thanks!