Created
March 5, 2018 05:20
-
-
Save anonymous/52812c6adfb7e5cf9b2343ae09651081 to your computer and use it in GitHub Desktop.
Created using browser-solidity: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://ethereum.github.io/browser-solidity/#version=soljson-v0.4.20+commit.3155dd80.js&optimize=false&gist=
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity ^0.4.18; | |
/** | |
* @title Ownable | |
* @dev The Ownable contract has an owner address, and provides basic authorization control | |
* functions, this simplifies the implementation of "user permissions". | |
*/ | |
contract Ownable { | |
address public owner; | |
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner); | |
/** | |
* @dev The Ownable constructor sets the original `owner` of the contract to the sender | |
* account. | |
*/ | |
function Ownable() public { | |
owner = msg.sender; | |
} | |
/** | |
* @dev Throws if called by any account other than the owner. | |
*/ | |
modifier onlyOwner() { | |
require(msg.sender == owner); | |
_; | |
} | |
/** | |
* @dev Allows the current owner to transfer control of the contract to a newOwner. | |
* @param newOwner The address to transfer ownership to. | |
*/ | |
function transferOwnership(address newOwner) public onlyOwner { | |
require(newOwner != address(0)); | |
OwnershipTransferred(owner, newOwner); | |
owner = newOwner; | |
} | |
} | |
/** | |
* @title Pausable | |
* @dev Base contract which allows children to implement an emergency stop mechanism. | |
*/ | |
contract Pausable is Ownable { | |
event Pause(); | |
event Unpause(); | |
bool public paused = false; | |
/** | |
* @dev Modifier to make a function callable only when the contract is not paused. | |
*/ | |
modifier whenNotPaused() { | |
require(!paused); | |
_; | |
} | |
/** | |
* @dev Modifier to make a function callable only when the contract is paused. | |
*/ | |
modifier whenPaused() { | |
require(paused); | |
_; | |
} | |
/** | |
* @dev called by the owner to pause, triggers stopped state | |
*/ | |
function pause() onlyOwner whenNotPaused public { | |
paused = true; | |
Pause(); | |
} | |
/** | |
* @dev called by the owner to unpause, returns to normal state | |
*/ | |
function unpause() onlyOwner whenPaused public { | |
paused = false; | |
Unpause(); | |
} | |
} | |
/** | |
* @title ERC20Basic | |
* @dev Simpler version of ERC20 interface | |
* @dev see https://github.com/ethereum/EIPs/issues/179 | |
*/ | |
contract ERC20Basic { | |
function totalSupply() public view returns (uint256); | |
function balanceOf(address who) public view returns (uint256); | |
function transfer(address to, uint256 value) public returns (bool); | |
event Transfer(address indexed from, address indexed to, uint256 value); | |
} | |
/** | |
* @title ERC20 interface | |
* @dev see https://github.com/ethereum/EIPs/issues/20 | |
*/ | |
contract ERC20 is ERC20Basic { | |
function allowance(address owner, address spender) public view returns (uint256); | |
function transferFrom(address from, address to, uint256 value) public returns (bool); | |
function approve(address spender, uint256 value) public returns (bool); | |
event Approval(address indexed owner, address indexed spender, uint256 value); | |
} | |
/** | |
* @title Basic token | |
* @dev Basic version of StandardToken, with no allowances. | |
*/ | |
contract BasicToken is ERC20Basic { | |
using SafeMath for uint256; | |
mapping(address => uint256) balances; | |
uint256 totalSupply_; | |
/** | |
* @dev total number of tokens in existence | |
*/ | |
function totalSupply() public view returns (uint256) { | |
return totalSupply_; | |
} | |
/** | |
* @dev transfer token for a specified address | |
* @param _to The address to transfer to. | |
* @param _value The amount to be transferred. | |
*/ | |
function transfer(address _to, uint256 _value) public returns (bool) { | |
require(_to != address(0)); | |
require(_value <= balances[msg.sender]); | |
// SafeMath.sub will throw if there is not enough balance. | |
balances[msg.sender] = balances[msg.sender].sub(_value); | |
balances[_to] = balances[_to].add(_value); | |
Transfer(msg.sender, _to, _value); | |
return true; | |
} | |
/** | |
* @dev Gets the balance of the specified address. | |
* @param _owner The address to query the the balance of. | |
* @return An uint256 representing the amount owned by the passed address. | |
*/ | |
function balanceOf(address _owner) public view returns (uint256 balance) { | |
return balances[_owner]; | |
} | |
} | |
/** | |
* @title Standard ERC20 token | |
* | |
* @dev Implementation of the basic standard token. | |
* @dev https://github.com/ethereum/EIPs/issues/20 | |
* @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol | |
*/ | |
contract StandardToken is ERC20, BasicToken { | |
mapping (address => mapping (address => uint256)) internal allowed; | |
/** | |
* @dev Transfer tokens from one address to another | |
* @param _from address The address which you want to send tokens from | |
* @param _to address The address which you want to transfer to | |
* @param _value uint256 the amount of tokens to be transferred | |
*/ | |
function transferFrom(address _from, address _to, uint256 _value) public returns (bool) { | |
require(_to != address(0)); | |
require(_value <= balances[_from]); | |
require(_value <= allowed[_from][msg.sender]); | |
balances[_from] = balances[_from].sub(_value); | |
balances[_to] = balances[_to].add(_value); | |
allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value); | |
Transfer(_from, _to, _value); | |
return true; | |
} | |
/** | |
* @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender. | |
* | |
* Beware that changing an allowance with this method brings the risk that someone may use both the old | |
* and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this | |
* race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards: | |
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729 | |
* @param _spender The address which will spend the funds. | |
* @param _value The amount of tokens to be spent. | |
*/ | |
function approve(address _spender, uint256 _value) public returns (bool) { | |
allowed[msg.sender][_spender] = _value; | |
Approval(msg.sender, _spender, _value); | |
return true; | |
} | |
/** | |
* @dev Function to check the amount of tokens that an owner allowed to a spender. | |
* @param _owner address The address which owns the funds. | |
* @param _spender address The address which will spend the funds. | |
* @return A uint256 specifying the amount of tokens still available for the spender. | |
*/ | |
function allowance(address _owner, address _spender) public view returns (uint256) { | |
return allowed[_owner][_spender]; | |
} | |
/** | |
* @dev Increase the amount of tokens that an owner allowed to a spender. | |
* | |
* approve should be called when allowed[_spender] == 0. To increment | |
* allowed value is better to use this function to avoid 2 calls (and wait until | |
* the first transaction is mined) | |
* From MonolithDAO Token.sol | |
* @param _spender The address which will spend the funds. | |
* @param _addedValue The amount of tokens to increase the allowance by. | |
*/ | |
function increaseApproval(address _spender, uint _addedValue) public returns (bool) { | |
allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue); | |
Approval(msg.sender, _spender, allowed[msg.sender][_spender]); | |
return true; | |
} | |
/** | |
* @dev Decrease the amount of tokens that an owner allowed to a spender. | |
* | |
* approve should be called when allowed[_spender] == 0. To decrement | |
* allowed value is better to use this function to avoid 2 calls (and wait until | |
* the first transaction is mined) | |
* From MonolithDAO Token.sol | |
* @param _spender The address which will spend the funds. | |
* @param _subtractedValue The amount of tokens to decrease the allowance by. | |
*/ | |
function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) { | |
uint oldValue = allowed[msg.sender][_spender]; | |
if (_subtractedValue > oldValue) { | |
allowed[msg.sender][_spender] = 0; | |
} else { | |
allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue); | |
} | |
Approval(msg.sender, _spender, allowed[msg.sender][_spender]); | |
return true; | |
} | |
} | |
/** | |
* @title Pausable token | |
* @dev StandardToken modified with pausable transfers. | |
**/ | |
contract PausableToken is StandardToken, Pausable { | |
function transfer(address _to, uint256 _value) public whenNotPaused returns (bool) { | |
return super.transfer(_to, _value); | |
} | |
function transferFrom(address _from, address _to, uint256 _value) public whenNotPaused returns (bool) { | |
return super.transferFrom(_from, _to, _value); | |
} | |
function approve(address _spender, uint256 _value) public whenNotPaused returns (bool) { | |
return super.approve(_spender, _value); | |
} | |
function increaseApproval(address _spender, uint _addedValue) public whenNotPaused returns (bool success) { | |
return super.increaseApproval(_spender, _addedValue); | |
} | |
function decreaseApproval(address _spender, uint _subtractedValue) public whenNotPaused returns (bool success) { | |
return super.decreaseApproval(_spender, _subtractedValue); | |
} | |
} | |
/** | |
* @title Mintable token | |
* @dev Simple ERC20 Token example, with mintable token creation | |
* @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120 | |
* Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol | |
*/ | |
contract MintableToken is StandardToken, Ownable { | |
event Mint(address indexed to, uint256 amount); | |
event MintFinished(); | |
bool public mintingFinished = false; | |
modifier canMint() { | |
require(!mintingFinished); | |
_; | |
} | |
/** | |
* @dev Function to mint tokens | |
* @param _to The address that will receive the minted tokens. | |
* @param _amount The amount of tokens to mint. | |
* @return A boolean that indicates if the operation was successful. | |
*/ | |
function mint(address _to, uint256 _amount) onlyOwner canMint public returns (bool) { | |
totalSupply_ = totalSupply_.add(_amount); | |
balances[_to] = balances[_to].add(_amount); | |
Mint(_to, _amount); | |
Transfer(address(0), _to, _amount); | |
return true; | |
} | |
/** | |
* @dev Function to stop minting new tokens. | |
* @return True if the operation was successful. | |
*/ | |
function finishMinting() onlyOwner canMint public returns (bool) { | |
mintingFinished = true; | |
MintFinished(); | |
return true; | |
} | |
} | |
/** | |
* @title Capped token | |
* @dev Mintable token with a token cap. | |
*/ | |
contract CappedToken is MintableToken { | |
uint256 public cap; | |
function CappedToken(uint256 _cap) public { | |
require(_cap > 0); | |
cap = _cap; | |
} | |
/** | |
* @dev Function to mint tokens | |
* @param _to The address that will receive the minted tokens. | |
* @param _amount The amount of tokens to mint. | |
* @return A boolean that indicates if the operation was successful. | |
*/ | |
function mint(address _to, uint256 _amount) onlyOwner canMint public returns (bool) { | |
require(totalSupply_.add(_amount) <= cap); | |
return super.mint(_to, _amount); | |
} | |
} | |
/** | |
* @title Burnable Token | |
* @dev Token that can be irreversibly burned (destroyed). | |
*/ | |
contract BurnableToken is BasicToken { | |
event Burn(address indexed burner, uint256 value); | |
/** | |
* @dev Burns a specific amount of tokens. | |
* @param _value The amount of token to be burned. | |
*/ | |
function burn(uint256 _value) public { | |
require(_value <= balances[msg.sender]); | |
// no need to require value <= totalSupply, since that would imply the | |
// sender's balance is greater than the totalSupply, which *should* be an assertion failure | |
address burner = msg.sender; | |
balances[burner] = balances[burner].sub(_value); | |
totalSupply_ = totalSupply_.sub(_value); | |
Burn(burner, _value); | |
} | |
} | |
contract DetailedERC20 is ERC20 { | |
string public name; | |
string public symbol; | |
uint8 public decimals; | |
function DetailedERC20(string _name, string _symbol, uint8 _decimals) public { | |
name = _name; | |
symbol = _symbol; | |
decimals = _decimals; | |
} | |
} | |
/** | |
* @title SafeERC20 | |
* @dev Wrappers around ERC20 operations that throw on failure. | |
* To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract, | |
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc. | |
*/ | |
library SafeERC20 { | |
function safeTransfer(ERC20Basic token, address to, uint256 value) internal { | |
assert(token.transfer(to, value)); | |
} | |
function safeTransferFrom(ERC20 token, address from, address to, uint256 value) internal { | |
assert(token.transferFrom(from, to, value)); | |
} | |
function safeApprove(ERC20 token, address spender, uint256 value) internal { | |
assert(token.approve(spender, value)); | |
} | |
} | |
/** | |
* @title TokenTimelock | |
* @dev TokenTimelock is a token holder contract that will allow a | |
* beneficiary to extract the tokens after a given release time | |
*/ | |
contract TokenTimelock { | |
using SafeERC20 for ERC20Basic; | |
// ERC20 basic token contract being held | |
ERC20Basic public token; | |
// beneficiary of tokens after they are released | |
address public beneficiary; | |
// timestamp when token release is enabled | |
uint256 public releaseTime; | |
function TokenTimelock(ERC20Basic _token, address _beneficiary, uint256 _releaseTime) public { | |
require(_releaseTime > now); | |
token = _token; | |
beneficiary = _beneficiary; | |
releaseTime = _releaseTime; | |
} | |
/** | |
* @notice Transfers tokens held by timelock to beneficiary. | |
*/ | |
function release() public { | |
require(now >= releaseTime); | |
uint256 amount = token.balanceOf(this); | |
require(amount > 0); | |
token.safeTransfer(beneficiary, amount); | |
} | |
} | |
/** | |
* @title TokenVesting | |
* @dev A token holder contract that can release its token balance gradually like a | |
* typical vesting scheme, with a cliff and vesting period. Optionally revocable by the | |
* owner. | |
*/ | |
contract TokenVesting is Ownable { | |
using SafeMath for uint256; | |
using SafeERC20 for ERC20Basic; | |
event Released(uint256 amount); | |
event Revoked(); | |
// beneficiary of tokens after they are released | |
address public beneficiary; | |
uint256 public cliff; | |
uint256 public start; | |
uint256 public duration; | |
bool public revocable; | |
mapping (address => uint256) public released; | |
mapping (address => bool) public revoked; | |
/** | |
* @dev Creates a vesting contract that vests its balance of any ERC20 token to the | |
* _beneficiary, gradually in a linear fashion until _start + _duration. By then all | |
* of the balance will have vested. | |
* @param _beneficiary address of the beneficiary to whom vested tokens are transferred | |
* @param _cliff duration in seconds of the cliff in which tokens will begin to vest | |
* @param _duration duration in seconds of the period in which the tokens will vest | |
* @param _revocable whether the vesting is revocable or not | |
*/ | |
function TokenVesting(address _beneficiary, uint256 _start, uint256 _cliff, uint256 _duration, bool _revocable) public { | |
require(_beneficiary != address(0)); | |
require(_cliff <= _duration); | |
beneficiary = _beneficiary; | |
revocable = _revocable; | |
duration = _duration; | |
cliff = _start.add(_cliff); | |
start = _start; | |
} | |
/** | |
* @notice Transfers vested tokens to beneficiary. | |
* @param token ERC20 token which is being vested | |
*/ | |
function release(ERC20Basic token) public { | |
uint256 unreleased = releasableAmount(token); | |
require(unreleased > 0); | |
released[token] = released[token].add(unreleased); | |
token.safeTransfer(beneficiary, unreleased); | |
Released(unreleased); | |
} | |
/** | |
* @notice Allows the owner to revoke the vesting. Tokens already vested | |
* remain in the contract, the rest are returned to the owner. | |
* @param token ERC20 token which is being vested | |
*/ | |
function revoke(ERC20Basic token) public onlyOwner { | |
require(revocable); | |
require(!revoked[token]); | |
uint256 balance = token.balanceOf(this); | |
uint256 unreleased = releasableAmount(token); | |
uint256 refund = balance.sub(unreleased); | |
revoked[token] = true; | |
token.safeTransfer(owner, refund); | |
Revoked(); | |
} | |
/** | |
* @dev Calculates the amount that has already vested but hasn't been released yet. | |
* @param token ERC20 token which is being vested | |
*/ | |
function releasableAmount(ERC20Basic token) public view returns (uint256) { | |
return vestedAmount(token).sub(released[token]); | |
} | |
/** | |
* @dev Calculates the amount that has already vested. | |
* @param token ERC20 token which is being vested | |
*/ | |
function vestedAmount(ERC20Basic token) public view returns (uint256) { | |
uint256 currentBalance = token.balanceOf(this); | |
uint256 totalBalance = currentBalance.add(released[token]); | |
if (now < cliff) { | |
return 0; | |
} else if (now >= start.add(duration) || revoked[token]) { | |
return totalBalance; | |
} else { | |
return totalBalance.mul(now.sub(start)).div(duration); | |
} | |
} | |
} | |
/** | |
* @title Math | |
* @dev Assorted math operations | |
*/ | |
library Math { | |
function max64(uint64 a, uint64 b) internal pure returns (uint64) { | |
return a >= b ? a : b; | |
} | |
function min64(uint64 a, uint64 b) internal pure returns (uint64) { | |
return a < b ? a : b; | |
} | |
function max256(uint256 a, uint256 b) internal pure returns (uint256) { | |
return a >= b ? a : b; | |
} | |
function min256(uint256 a, uint256 b) internal pure returns (uint256) { | |
return a < b ? a : b; | |
} | |
} | |
/** | |
* @title SafeMath | |
* @dev Math operations with safety checks that throw on error | |
*/ | |
library SafeMath { | |
/** | |
* @dev Multiplies two numbers, throws on overflow. | |
*/ | |
function mul(uint256 a, uint256 b) internal pure returns (uint256) { | |
if (a == 0) { | |
return 0; | |
} | |
uint256 c = a * b; | |
assert(c / a == b); | |
return c; | |
} | |
/** | |
* @dev Integer division of two numbers, truncating the quotient. | |
*/ | |
function div(uint256 a, uint256 b) internal pure returns (uint256) { | |
// assert(b > 0); // Solidity automatically throws when dividing by 0 | |
uint256 c = a / b; | |
// assert(a == b * c + a % b); // There is no case in which this doesn't hold | |
return c; | |
} | |
/** | |
* @dev Substracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend). | |
*/ | |
function sub(uint256 a, uint256 b) internal pure returns (uint256) { | |
assert(b <= a); | |
return a - b; | |
} | |
/** | |
* @dev Adds two numbers, throws on overflow. | |
*/ | |
function add(uint256 a, uint256 b) internal pure returns (uint256) { | |
uint256 c = a + b; | |
assert(c >= a); | |
return c; | |
} | |
} | |
contract ERC20Token is StandardToken { | |
bool public isWingBase = true; | |
string public constant name = 'WingToken'; | |
string public constant symbol = 'WIT'; | |
uint8 public constant decimals = 18; | |
uint256 public constant INITIAL_SUPPLY = 10000 * (10 ** uint256(decimals)); | |
function ERC20Token() public{ | |
totalSupply_ = INITIAL_SUPPLY; | |
balances[msg.sender] = INITIAL_SUPPLY; | |
Transfer(0x0, msg.sender, INITIAL_SUPPLY); | |
} | |
} | |
contract Demo { | |
ERC20Token public erc20Token = ERC20Token(address(this)); | |
function demoTransfer() public { | |
erc20Token.transfer(msg.sender,1); | |
} | |
function getPropsCount(address _address) public view returns(uint256 tokenCount) { | |
tokenCount = erc20Token.balanceOf(_address); | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment