default.nix

{ clangStdenv, clang, gcc7, fetchFromGitHub, scons, pkgconfig, xlibs
, freetype, openssl, alsaLib
, libpulseaudio, mesa_glu, zlib }:

let
  stdenv = clangStdenv;
in stdenv.mkDerivation rec {
  name    = "godot-${version}";
  version = "2.1.4-stable";

  src = fetchFromGitHub {
    owner  = "godotengine";
    repo   = "godot";
    rev    = version;
    sha256 = "0d2zczn5k7296sky5gllq55cxd586nx134y2iwjpkqqjr62g0h48";
  };

  buildInputs = [
    clang gcc7 scons pkgconfig freetype openssl alsaLib libpulseaudio mesa_glu zlib
  ] ++ (with xlibs; [
    libX11 libXcursor libXinerama libXrandr libXrender
  ]);

  patches = [ ./pkg_config_additions.patch ];

  enableParallelBuilding = true;

  buildPhase = ''
    scons platform=x11 use_llvm=yes prefix=$out -j $NIX_BUILD_CORES
  '';

  installPhase = ''
    mkdir $out/bin -p
    cp bin/godot.* $out/bin/
  '';

  meta = {
    homepage    = "https://godotengine.org";
    description = "Free and Open Source 2D and 3D game engine";
    license     = stdenv.lib.licenses.mit;
    platforms   = stdenv.lib.platforms.linux;
  };
}

pkg_config_additions.patch

+++ build/platform/x11/detect.py
@@ -139,6 +139,10 @@
     env.ParseConfig('pkg-config xinerama --cflags --libs')
     env.ParseConfig('pkg-config xcursor --cflags --libs')
     env.ParseConfig('pkg-config xrandr --cflags --libs')
+    env.ParseConfig('pkg-config xrender --cflags --libs')
+    env.ParseConfig('pkg-config osmesa --cflags')
+    env.ParseConfig('pkg-config glu --cflags --libs')
+    env.ParseConfig('pkg-config zlib --cflags --libs')

     if (env['builtin_openssl'] == 'no'):
         # Currently not compatible with OpenSSL 1.1.0+