Antlr4 grammar file to parser C-style "typedef struct { ... } name;" definitions

20131225-antlr4-cstruct-usertype.g4

grammar UserType;

@header {
package test;
}

@lexer::members{
public static final int WHITESPACE = 1;
public static final int COMMENTS = 2;
}

userStructTypeDefs : userStructTypeDef+
    ;
userStructTypeDef : 'typedef' 'struct' '{' structFieldDecl+ '}' NAME ';'
    ;
structFieldDecl : primitiveType NAME ';'                     # PrimitiveFieldDecl
    | arrayElementType NAME '[' dim1 ']' ';'                 # Array1DFieldDecl
    | arrayElementType NAME '[' dim1 ']' '[' dim2 ']' ';'    # Array2DFieldDecl
    | userType NAME ';'                                      # UserTypeFieldDecl
    ;
arrayElementType : primitiveType #PrimitiveArrayElementType
    | userType                   #UserArrayElementType
   ;
dim1 : NUMBER ;
dim2 : NUMBER ;
primitiveType : 'int' 
    | 'double' 
    | 'char' 
    | 'CHAR' 
    | 'BOOL' 
    | 'DWORD' 
    ; 
userType : NAME ;

WS : [ \t\r\n]+ -> channel(WHITESPACE);
COMMENT : '//' ~[\n]+  -> channel(COMMENTS);
NUMBER : [0-9]+ ;
NAME : [a-z_A-Z][a-z_A-Z0-9]* ;