PKGBUILD

# Maintainer: OK100 <ok100 at lavabit dot com>
# Previous Maintainer: Valère Monseur <valere dot monseur at ymail dot com>

pkgname=compton-git
_gitname=compton
pkgver=2014.02.27.g8a5becf
pkgrel=1
pkgdesc="X Compositor (a fork of xcompmgr-dana)"
arch=(i686 x86_64)
url="https://github.com/chjj/compton"
license=('MIT')
depends=('libgl' 'libdbus' 'libxcomposite' 'libxdamage' 'libxrandr' 'pcre' 'libconfig' 'libxinerama')
optdepends=('xorg-xprop: for compton-trans'
            'xorg-xwininfo: for compton-trans')
makedepends=('git' 'asciidoc')
source=("git://github.com/chjj/compton.git" "https://gist.githubusercontent.com/richardgv/9529221/raw/c8e01f95865ff8dba562a9c8b0b7b70e0c42b8ed/compton-xsync-fence.patch")
md5sums=('SKIP'
         '7b17df4b3e20e4a551151616103e0e6a')

pkgver() {
    cd "${srcdir}/${_gitname}"
    git log -1 --format="%cd.g%h" --date=short | sed 's/-/./g'
}

prepare() {
  cd "$srcdir/$_gitname"
  patch -p1 < "$srcdir/compton-xsync-fence.patch"
}

build() {
  cd "$srcdir/$_gitname"
  make PREFIX=/usr
  make docs
}

package() {
  cd "$srcdir/$_gitname"

  make PREFIX="$pkgdir/usr" install

  # install license
  install -D -m644 "LICENSE" "$pkgdir/usr/share/licenses/$_gitname/LICENSE"

  # example conf
  install -D -m644 "compton.sample.conf" "$pkgdir/etc/xdg/compton.conf.example"
}