default.nix

with import <nixpkgs> {};

let
  stuff = self: {
    callPackage = pkgs.newScope self;
    jerasure = self.callPackage ./jerasure.nix {};
    gf-complete = self.callPackage ./gf-complete.nix {};
    something = self.callPackage ./something.nix {};
  };
in lib.fix stuff

gf-complete.nix

{ stdenv, fetchurl, unzip, autoreconfHook }:

stdenv.mkDerivation {
  name = "gf-complete";
  src = fetchurl {
    url = "http://jerasure.org/jerasure/gf-complete/repository/archive.zip";
    sha256 = "10cnj4yvlqrbmadyqg9cvrv2bwlciq70nzfambj4x6m7zmpbx5dx";
    name = "gf-complete.zip";
  };
  nativeBuildInputs = [ unzip autoreconfHook ];
}

jerasure.nix

{ stdenv, fetchurl, unzip, autoreconfHook, gf-complete }:

stdenv.mkDerivation {
  name = "jerasure";
  src = fetchurl {
    url = "http://lab.jerasure.org/jerasure/jerasure/repository/archive.zip?ref=master";
    sha256 = "0jv4c9fp309afzb99bjkgsyq9y0hwbnjshgnjmzilq91lh9a6ahh";
    name = "master.zip";
  };
  nativeBuildInputs = [ unzip autoreconfHook ];
  buildInputs = [ gf-complete ];
}

something.nix

{ stdenv, jerasure }:

stdenv.mkDerivation {
  name = "something";
  src = ./.;
  buildInputs = [ jerasure ];
  NIX_CFLAGS_COMPILE = "-I${jerasure}/include/jerasure";
}