Start IE browser maximized (can be used with automation)

start-ie-maximized.bat

@echo OFF
setlocal ENABLEEXTENSIONS

set IE11Maximized=2C0000000200000003
set KEY_NAME="HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main"
set VALUE_NAME=Window_Placement

:: REG QUERY "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v Window_Placement

for /f "usebackq tokens=3" %%A in (`REG QUERY %KEY_NAME% /v %VALUE_NAME% 2^>nul`) do (
    set ValueOrig=%%A
)

if not defined ValueOrig goto end

set ValueFirstPart=%ValueOrig:~0,18%
set ValueSecondPart=%ValueOrig:~18%
set ValueFinal=%IE11Maximized%%ValueSecondPart%

@echo Original value   = %ValueOrig%
@echo Value to replace = %ValueFirstPart%
@echo Value to keep    = %ValueSecondPart%
@echo Final value to write = %ValueFinal%

:: REG ADD "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v Window_Placement /t REG_BINARY /d 2C0000000200000003000000FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFE1000000190000007B07000078030000 /f

REG ADD %KEY_NAME% /v %VALUE_NAME% /t REG_BINARY /d %ValueFinal% /f

:end:

This can be used with automation tasks.
It must be executed while IE browser is not running, otherwise the registry value will be overwritten when IE window is closed.