Made a calculator using the yecc and leex.

README

$ /path/to/reia/bin/leex calc_scan.xrl
$ /path/to/reia/bin/yecc calc_parse.yrl
$ erlc calc_scan.erl
$ erlc calc_parse.erl
$ erlc calc_eval.erl

$ erl
1> {ok, Scan, _Line} = calc_scan:string("(1 + 2) * 3 - 4").
2> {ok, Exp} = calc_parse:parse(Scan).
3> calc_eval:eval(Exp).

calc_eval.erl

-module(calc_eval).
-author('cooldaemon@gmail.com').

-export([eval/1]).

eval({{'+', _}, Expr1, Expr2}) ->
  eval(Expr1) + eval(Expr2);
eval({{'-', _}, Expr1, Expr2}) ->
  eval(Expr1) - eval(Expr2);
eval({{'*', _}, Expr1, Expr2}) ->
  eval(Expr1) * eval(Expr2);
eval({{'/', _}, Expr1, Expr2}) ->
  eval(Expr1) / eval(Expr2);
eval({integer, _, Expr}) ->
  Expr.

calc_parse.yrl

Nonterminals
expression term block.

Terminals
integer
'(' ')' '+' '-' '*' '/'.

Rootsymbol expression.

expression -> term                : '$1'.
expression -> expression '+' term : {'$2', '$1', '$3'}.
expression -> expression '-' term : {'$2', '$1', '$3'}.

term -> block          : '$1'.
term -> term '*' block : {'$2', '$1', '$3'}.
term -> term '/' block : {'$2', '$1', '$3'}.

block -> '(' expression ')' : '$2'.
block -> integer            : '$1'.

calc_scan.xrl

Definitions.
Dig = [0-9]

Rules.
({Dig}{Dig}*) : {token, {integer, TokenLine, list_to_integer(TokenChars)}}.

\+ : {token, {'+', TokenLine}}.
\- : {token, {'-', TokenLine}}.
\* : {token, {'*', TokenLine}}.
\/ : {token, {'/', TokenLine}}.
\( : {token, {'(', TokenLine}}.
\) : {token, {')', TokenLine}}.

(.|\n) : skip_token.