Janitor - J code formatter

janitor.ijs

#!/usr/bin/env jconsole

NB. No space before these tokens
bef =: ;: ') @ @. @: & &. &: &.: " ` ;. !. !: / /. \ ~ }'
NB. No space after these tokens
aft =: ;: '( @ @. @: & &. &: &.: " ` ;. !. !:'

Cont =: {{ +./ ((dltb > x) (-: ;)"1 0 y) }}

Fmt =: {{
    tokens =. ;: y
    res =. {. tokens
    for_next. }. tokens do.
        last =. > {. res
        if. -. ((last Cont aft) +. (next Cont bef)) do.
            next =. ' ', dltb ; next
        end.
        res =. res ;~ > next
    end.
    '' joinstring |. res
}}

NB. Reads boxed lines from ARGV filenames, otherwise from STDIN
ARGLINES =: {{ <;._2 stdin _ }}`{{ ,/ ('b' fread ])@> 2 }. y }}@.(2 < #)

MAIN =: {{
    for_line. ARGLINES y do.
        indent =. ' ' #~ {. I. ' ' ~: > line
        if. ((line_index -: 0) *. ('#' -: {. > line)) do.
            echo > line
            continue.
        end.
        echo indent , Fmt > line
    end.
}}

MAIN ARGV

exit 0

Better version using j-lex

#!/usr/bin/env jconsole

load 'tangentstorm/j-lex'

Fmt =: {{)m
    tokens =. ;: y
    parts =. jtype_jlex_@> tokens
    rep =: ; (+/ 'DP' =/ parts)} (<"0 parts) ,: ({.&.> tokens)

    if. 1 > # tokens do.
        EMPTY return.
    end.
    s =. 0,~ (<: # tokens) $ 1

    NB. No space after open paren, conj
    s =. s *.      rep -.@e. '(c'
    NB. No space before close paren, conj, adverb
    s =. s *. 1 |. rep -.@e. ')ca'

    NB. No space around : :. ::
    s =. s +. 0,~ 2 ~:/\ tokens e. ;: ': :. ::'

    NB. No space before .
    s =. s +. 1 |. tokens e. ;: '.'

    NB. after close paren (except adjacent close paren when preceeded by '{{')
    s =. s - (Rs rep e. '{') *. rep e. ')'

    ; tokens #!.(<' ')~ (# tokens) {. 1 j. 0,~ }: s
}}

ARGLINES =: {{ <;._2 stdin _ }}`{{ ,/ ('b' fread ])@> 2 }. y }}@.(2 < #)

MAIN =: {{
    for_line. ARGLINES y do.
        indent =. ' ' #~ {. I. ' ' ~: > line
        if. ((line_index -: 0) *. ('#' -: {. > line)) do.
            echo > line
            continue.
        end.
        echo indent , Fmt > line
    end.
}}

MAIN ARGV

exit 0