Extract Presenter Notes

Extract Presenter Notes.applescript

(*
 Extract presenter notes of the front most Keynote document and save to Desktop as Markdown file.
 Created by 1024jp on 2019-03-16.
 © 2019 1024jp
*)


-- collect presenter notes
tell front document of application "Keynote"
	set thePresentationTitle to name
	set presenterNotes to "# " & name & return & return
	
	repeat with i from 1 to count of slides
		repeat 1 times -- # fake loop for loop continue
			tell slide i
				if presenter notes is "" then exit repeat
				
				set theTitle to "## " & i & ". " & object text of default title item
				set presenterNotes to presenterNotes & theTitle & return & return & presenter notes & return & return
			end tell
		end repeat
	end repeat
end tell

-- create path to file
set theFileName to "presenterNotes-" & thePresentationTitle & ".md"
set theFilePath to (path to desktop folder as text) & theFileName

-- save to the file
try
	set theFile to open for access theFilePath with write permission
on error
	close access file theFilePath
	return
end try
set eof of theFile to 0
write presenterNotes to theFile as «class utf8»
close access theFile