PuzzleTech 0.74 (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

(-
 - Of Will and Blood
 - version 0.22
-)

title [0.22] Of Will and Blood
author 0x77
homepage 0x77.bit

background_color #777
text_color #FFF

realtime_interval .2

( Disable while editing )
zoomscreen 13x13
run_rules_on_level_start

( Enable (maybe?) while editing )
(verbose_logging)
(debug)

========
OBJECTS
========
( Background )
BACKGROUND .
BLACK

( HUD )
BAR_L
#D6D6D6
00000
0....
0....
0....
00000
BAR_M
#D6D6D6
00000
.....
.....
.....
00000
BAR_R
#D6D6D6
00000
....0
....0
....0
00000

STAT_HP 0
#A81E1E
STAT_ST 1
#2270A8

( Menu )
CURSOR +
#333
00.00
0...0
.....
0...0
00.00

M_BG *
#777
M_ITEM_BG :
#AAA
M_ITEM_CARRY ;
#AAA

M_MAIN0
#333
.....
.000.
.000.
.0.0.
.....
M_MAIN1
#333
.....
000.0
0.0.0
00..0
.....
M_MAIN2
#333
.....
00.0.
.0.0.
.0.00
.....
M_MAIN3
#333
.....
0....
0....
0....
.....

( Tiles )
EMPTY0
TRANSPARENT
EMPTY1
TRANSPARENT
EMPTY2
TRANSPARENT
EMPTY3
TRANSPARENT
EMPTY4
TRANSPARENT
EMPTY5
TRANSPARENT

GRASS ,
#577a48
GRASS_A0
#658C55 #45603A
.....
.0...
.1...
...0.
...1.
GRASS_A1
#658C55 #45603A
.....
..0..
.01.0
.1..1
.....
GRASS_A2
#658C55 #45603A
..0.0
..101
...1.
.0...
.1...
GRASS_A3
#658C55 #45603A
.....
.....
...0.
...1.
.....
GRASS_A4
#658C55 #45603A
....0
....1
..0..
..1..
.....

WATER ~
#39BDF0 #36CFF6 #33B0ED
01000
00020
00100
20001
00010

WATER0
#39BDF0 #36CFF6 #33B0ED
00200
20010
02000
01020
00000

WATER1
#39BDF0 #36CFF6 #33B0ED
01000
00020
00100
20001
00010

TREE
#82501C #7C974A #9AB34B
22111
11211
1111.
.11..
..0..

TREE_T
#7C974A #9AB34B #C2D651
..2..
..2..
.21..
.101.
2110.

WOOD_WALL
#8B6A34 #A77F3E
00100
11111
10000
11111
00010

WOOD_FLOOR
#A77F3E

( Items )
I_WOOD
#8B6A34 #A77F3E
.....
..1..
1.01.
.01..
..0..

I_MEAT
DARKBROWN WHITE GRAY
.....
..00.
.000.
.00..
.....

I_HEART
LIGHTRED RED DARKRED
.1.1.
10112
11112
.112.
..2..

( Entities )
PLAYER @
#7C3905 #000000 #0085BD #FFCDA3 #F6B78B
.444.
22222
32223
.000.
.1.1.

PLAYER_H &
#F6B78B #FFCDA3 #000000 #BC4700
.....
.....
.3333
30212
30111

PIG
LIGHTRED
.....
...00
...00
.000.
.0.0.

( Overlays )
B0
GRAY
.....
.....
..0..
.....
.....

B1
GRAY
.....
.0.0.
..0..
.0.0.
.....

B2
GRAY WHITE
0...0
.1.1.
..1..
.1.1.
0...0

B3
GRAY WHITE
1...1
.1.1.
..1..
.1.1.
1...1

BLOOD0
RED DARKRED
.....
.10..
..1..
1....
...0.

BLOOD1
RED DARKRED
.....
00.1.
.11..
.....
.0...

BLOOD2
RED DARKRED
.....
...0.
.....
.01..
.....

BLOOD3
RED DARKRED
....1
.0...
..1..
.....
.0...

( Tokens )
R_TICK '
TRANSPARENT
M_TICK "
TRANSPARENT

M_ON £
TRANSPARENT
M_TP
TRANSPARENT

T_MENU ¢
TRANSPARENT
T_HUD -
TRANSPARENT

X
TRANSPARENT
Y
TRANSPARENT
Z
TRANSPARENT

SPAWN ¬
TRANSPARENT

U
TRANSPARENT
D
TRANSPARENT
L
TRANSPARENT
R
TRANSPARENT

D0
TRANSPARENT
D1
TRANSPARENT
D2
TRANSPARENT
D3
TRANSPARENT

( Special )
BLOCK #
TRANSPARENT

CARRY /
#777

=======
LEGEND
=======
( HUD )
STAT = STAT_HP or STAT_ST
BAR  = BAR_L or BAR_M or BAR_R
HUD  = STAT or BAR

( Menu )
MENU = M_BG or M_ITEM_BG or M_ITEM_CARRY
M_MAIN = M_MAIN0 or M_MAIN1 or M_MAIN2 or M_MAIN3

$ = M_BG and M_TP

( Tiles )
EMPTY   = EMPTY0 or EMPTY1 or EMPTY2 or EMPTY3 or EMPTY4 or EMPTY5
GRASS_A = EMPTY0 or EMPTY1 or EMPTY2 or GRASS_A0 or GRASS_A1 or GRASS_A2 or GRASS_A3 or GRASS_A4
WATER_T = WATER or WATER0 or WATER1

TILE = GRASS or WATER_T or WOOD_FLOOR
SOLID = WATER_T or TREE or WOOD_WALL
BREAKABLE = TREE or WOOD_WALL

T = GRASS and TREE

( Entity Effects )
BLOOD = BLOOD0 or BLOOD1 or BLOOD2 or BLOOD3
ENTITY_FX = BLOOD or EMPTY

( Block effects )
BREAK = B0 or B1 or B2 or B3
BLOCK_FX = BREAK or EMPTY

( Entities )
ENTITY = PIG
DIES = PIG

P = GRASS and PIG

( Items )
ITEM    = I_WOOD or I_MEAT or I_HEART
I_BLOCK = M_BG or ITEM or CARRY

( Tokens )
TOKEN = X or Y or Z or U or D or L or R
DIR   = U or D or L or R
DMG   = D0 or D1 or D2 or D3

( Special )
THING = PLAYER or ENTITY or SOLID

=======
SOUNDS
=======
SFX0 71332504 ( Hurt )
SFX1 62586907 ( Tree hit )
SFX2 37514104 ( Block hit )
TREE DESTROY 99529902

(
48745102 WATR
90861700 COIN
12065107 ITEM
)

================
COLLISIONLAYERS
================
( BG )
BACKGROUND

( Tiles )
TILE

( Entity effects )
ENTITY_FX

( Tile effects )
EMPTY GRASS_A

( Items )
M_ITEM_BG M_ITEM_CARRY
ITEM

( Solids and entities )
SOLID ENTITY

( Block effects )
BLOCK_FX

( Player )
PLAYER PLAYER_H

( Overlays )
TREE_T

( HUD )
STAT
BAR

( Menu )
M_BG
CURSOR
M_MAIN

( Tokens )
R_TICK M_TICK M_ON M_TP T_HUD T_MENU
X
Y
Z
DIR
DMG

( Special )
BLOCK CARRY SPAWN

======
RULES
======
( Realtime fix )
[ STATIONARY @ ] ["] -> [        @ ] [']
[ MOVING     @ ] ['] -> [ MOVING @ ] ["]

( Camera fix )
UP    [ # | # || # ] -> [ ||| # U X ]
DOWN  [ # | # || # ] -> [ ||| # D ]
LEFT  [ # | # || # ] -> [ ||| # L ]
RIGHT [ # | # || # ] -> [ ||| # R ]

RIGHT [ # U X ||||||| ] -> [ # U ||||||| ¬ ]

( Player )
UP [ ¬ | TILE ] -> [ @ | TILE & ]

[ @ X ] -> [ @ ]

[ ACTION @ NO X ] [ M_TP ] [ + I_WOOD ] [ £ U X ] -> [ @ X ] [ WOOD_WALL M_TP ] [ + ] [ £ U ]

[ ACTION @ NO X ] [ £ U X ] [ + NO ITEM ] -> [ @ X ] [ £ U   ] [ + ]
[ ACTION @ NO X ] [ £ U   ]               -> [ @ X ] [ £ U X ]

[ £ U X ] [ > @ ] [ + ] -> [ £ U X ] [ @ ] [ > + ]

[ # U | ... | UP    @ ] -> [ # U | ... | @ ]
[ # D | ... | DOWN  @ ] -> [ # D | ... | @ ]
[ # L | ... | LEFT  @ ] -> [ # L | ... | @ ]
[ # R | ... | RIGHT @ ] -> [ # R | ... | @ ]

[ > @ | NO THING ] [ & ] -> [ > @ | NO THING ] [ > & ]

( Menu )
DOWN [ £ NO TOKEN | X | ] -> [ £ U Y || ¢ X ]
DOWN [ £ NO TOKEN | Y | ] -> [ £ D Y || ¢ Y ]

( Main menu )
RIGHT [ ¢ X ||||| ] -> [ || M_MAIN0 | M_MAIN1 | M_MAIN2 | M_MAIN3 ]

RIGHT [ £ U Y ||||||| ] -> [ £ U ||||||| $ U Y ]
DOWN  [ $ U Y ||||||| ] -> [     ||||||| $ U ]

LATE [ £ U    X ] [ $ U  ] [ @ X ]     -> [ £ U X ] [ @ M_BG + ] [ M_TP ]
LATE [ £ U NO X ] [ M_TP ] [ @ X ] [+] -> [ £ U   ] [ @        ] [ $ U  ] []

( Items )
[ @ ITEM ] [ ; NO ITEM ] -> [@] [ ; ITEM X ]

LEFT [ ITEM X | NO I_BLOCK ] -> [ | ITEM X ]
RIGHT [ U | / | ITEM X ] [ NO ITEM | / | U ] -> [ U | / | ] [ ITEM X | / | U ]
LEFT [ ITEM X | NO I_BLOCK ] -> [ | ITEM X ]
RIGHT [ D | / | ITEM X ] [ NO ITEM | / | D ] -> [ D | / | ] [ ITEM X | / | D ]
LEFT [ ITEM X | NO I_BLOCK ] -> [ | ITEM X ]
RIGHT [ L | / | ITEM X ] [ NO ITEM | / | L ] -> [ L | / | ] [ ITEM X | / | L ]
LEFT [ ITEM X | NO I_BLOCK ] -> [ | ITEM X ]
RIGHT [ R | / | ITEM X ] [ NO ITEM | / | R ] -> [ R | / | ] [ ITEM X | / | R ]
LEFT [ ITEM X | NO I_BLOCK ] -> [ | ITEM X ]

( Tiles )
[ GRASS NO GRASS_A ] -> [ GRASS RANDOM GRASS_A ]

( Trees )
UP [ TREE | ] -> [ TREE | TREE_T ]
LATE DOWN [ TREE_T | NO TREE ] -> [ | ]

( Breakable tiles )
[ ^ @ | BREAKABLE BREAK ] -> [ ^ @ | BREAKABLE ]
[ < @ | BREAKABLE BREAK ] -> [ < @ | BREAKABLE ]
[ v @ | BREAKABLE BREAK ] -> [ v @ | BREAKABLE ]

[ > @ | TREE      B3 ] -> [ @ | I_WOOD ]
[ > @ | WOOD_WALL B3 ] -> [ @ | I_WOOD ]

[ > @ | BREAKABLE B2 ] -> [ @ | BREAKABLE B3 ] SFX1
[ > @ | BREAKABLE B1 ] -> [ @ | BREAKABLE B2 ] SFX1
[ > @ | BREAKABLE B0 ] -> [ @ | BREAKABLE B1 ] SFX1
[ > @ | BREAKABLE    ] -> [ @ | BREAKABLE B0 ] SFX1

( Killing entities )
[ > @ | PIG D3 ] [ & ] -> [ @ | I_MEAT RANDOM BLOOD ] [ & ] SFX0

[ > @ | DIES D2 ] [ & ] -> [ @ | DIES D3 RANDOM BLOOD ] [ & ] SFX0
[ > @ | DIES D1 ] [ & ] -> [ @ | DIES D2 RANDOM BLOOD ] [ & ] SFX0
[ > @ | DIES D0 ] [ & ] -> [ @ | DIES D1 RANDOM BLOOD ] [ & ] SFX0
[ > @ | DIES ]    [ & ] -> [ @ | DIES D0 RANDOM BLOOD ] [ & ] SFX0

( Water animation )
['][ WATER_T R ] -> ['][ RANDOM WATER_T ]

['][ WATER_T L ] -> ['][ WATER_T R ]
['][ WATER_T D ] -> ['][ WATER_T L ]
['][ WATER_T U ] -> ['][ WATER_T D ]
['][ WATER_T Z ] -> ['][ WATER_T U ]
['][ WATER_T Y ] -> ['][ WATER_T Z ]
['][ WATER_T X ] -> ['][ WATER_T Y ]
['][ WATER_T NO TOKEN NO DIR ] -> ['][ WATER_T X ]

( Fix player collision )
[ > @ | THING ] -> [ @ | THING ]

( HUD )
RIGHT [ - |||||         ] -> [ -         | BAR_L 0 | BAR_M 0 | BAR_M 0 | BAR_M 0 | BAR_R 0 ]
RIGHT [ - ||||||||||||| ] -> [   ||||||||| BAR_L 1 | BAR_M 1 | BAR_M 1 | BAR_M 1 | BAR_R 1 ]

[ > @ ] [ HUD ] -> [ > @ ] [ > HUD ]

==============
WINCONDITIONS
==============

=======
LEVELS
=======
£.............."......#.##.....................................................................
x*************..~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
.*************..~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
.*************..~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
.*************..~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
.*************..~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
.*************..~~~~~~,~,~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~,,,~~~~~~~~~~~~~~~~~~~~~~~~.
.*************.#~~~~~,,,,,,,~~,,~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~,,,,,t,,,~~~~~~,~,~~~~~~~~~~~~~.
.*:::::::::::/R.~~~~~,,,,~,,~,,,,,~~~~~~~~~~~,~~~,~~~~~~~~~~~~~~,,,t,,,~~~~~,~,,~~,,,,~~~~~~~~.
R/:::::::::::/L#~~~~~~,,,,,,,,,,,t~~~~~,,,t,,,~~,,t~t~~~~~~~t~~~~~,,,~~~~~t~,,,~~,,,t,~~~~~~~~.
L/:::::::::::/D#~~~~~~,,,,,,,,,,,,,,~,,,,t,t,,,,,,,,,~~~~~~~,t,,~~~~~~~~~,,,,,,~~,,t,,,~~~~~~~.
D/:::::::::::/U.~~~~,,,,,,,t,,,,,,,t,,,t,,,,,,p,,t,t,,,~,~,,,,,,~~~~~~,~,p,,t,~~,,,,,,,,~~~~~~.
U/::::::::::;*..~~~~~~~,,,,,tt,,t,,,,t,,,,,,,,,,,,,,,,t,,,,,,t,tt,~,~,t,,,,,t,,~,t,,,,,~~~~~~~.
.*************.-~~~~~~~~,,,,,,,t,,,,t,,,,,,,,,,t,,tt,,,,,,,,,t,,t,,p,,t,,,,,,,,~,,,,,,~~~~~~~~.
................~~~~~~~~,,,,,,,,,,,,,,,,t,,t,,,t,,,,,,,,,,p,,,t,,,,,,,,,,,,,t,,~~,t,p,~~~~~~~~.
................~~~~~~~~,,,,~t,,,p,,,,,,,,,,,,tt,,,,,,,,tt,,,,,,,,,,,,,,t,,,,,~,~,,,,,~,~~~~~~.
................~~~~~~~,t,~,,~,,,,,,,,,t,,,,,,,t,t,,,,t,t,,,,,,,p,,,t,,,,,t,,~,~,,,,t,~~~~~~~~.
................~~~~~~~,,,~,~~,,,,,t,tt,,,,,,,,,,t,,t,,,,,,,,,,,,,,,,,,,,,t,,,tt,,,,,,,~~~~~~~.
................~~~~~~,,,~t,t,,,,,,,,,,,t,,,,p,,,,,,,,,,,,,t,,,,,,t,,tt,,,,t,,,,,,,,,,,~~~~~~~.
................~~~~~~,,~~~~,,,,t,,,,p,,,,t,,,,,,,t,t,,,,,t,t,,,,,,,t,t,,~~~~,,,,,,,,,,,~~~~~~.
................~~~~~~~,~~~,,,,,t,,,,,,t,,,,,,,,,,,,,,t,,,,,,,,t,,,,,,,~~~~~~~,t,t,,,~~,~~~~~~.
................~~~~~~,,~~~~,,,,,,,t,,,t,,,,,,,,,,,,,,t,,,,,,,,,,,,,,p~~~~~~~~,,,,,t,,~~~~~~~~.
................~~~~~~,~~~,,,~,,,,,,,,,,,,,,,t,,t,,,,,,,t,,,,t,,t,,,,~~~~~~~~~~,,,,,,,~~~~~~~~.
................~~~~~~,~~,,,~~~,,,t,,,,~,,,,t,t,,,,,,,tt,,,,,,,,,,,,~~~~~~~~~~,t,,,,,t~~~~~~~~.
................~~~~~~~~~,t,~~t,,t,,t,,,~,,,,,t,,,,t,,,,,,,,t,,,,,,t,~~~~~~~~,,,,,,,,,,~~~~~~~.
................~~~~~,~~,,,,~~,,,,,,,,,,,~,t,t,,,,,,t,,t,,,,,,t,,,,t,~~~~~~~~~~,,,,p,,,~~~~~~~.
................~~~~,,,~,t,,,~,,,,,,,,t,,~,,,,,,,,t,,p,,,,,,,t,,,,,,,t~~~~~~~~~,,,,,,,,~~~~~~~.
................~~~,t,,~,,,,,,,t,,,,,,,,,~t,tt,,t,t,,,,,,t,,,,,,,,,,,,,,,~~,,~~~,,,,,,~~~~~~~~.
................~~~,,,~~,,,t,,,,,,,,t,,p,~,t,,,~~,,,,,,,,,,,t,t,,,t,,t,,,,,,,~,~~,t,,,~~~~~~~~.
................~~~~,~~~,p,,,,,t,,,t,,,,,~~t~~~~~~,t,,,,,,t,,,,,t,,,,,,,,,,,,~t,~~,,,,,~~~~~~~.
................~~~~~~,,,,,,,,,,,,,,,,,,,~~,,,~~~~~,,tt,,,,,t,,,,,,,,,,,,,,~~~,,,~,,,,~~~~~~~~#
................~~~~~~~,,,,t,,,,~,,,,t,,~~,,,,,,,,,p,,,,t,,,,t,,,p,,,,t,,t,~t~,,~~~,t,,,~~~~~~#
................~~~~~~~,t,,,~~~,~~~,,,,,~,,,,,t,,,,,,,,,,~~,~~~,~,,,,~~~,,,~~~p,~~,~,,t~~~~~~~.
................~~~~~~~,~~~~~~~~~~~~~~~,~~~~,,~,~~~,,,~,~~~~~~~~~~~~~~~~~,~~,,~~~~~~,~~~~~~~~~#
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
................~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~.
...................................................................................##.#........

£.............."......#.##..............................
X*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************.#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*:::::::::::*..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*:::::::::::*.#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*:::::::::::*.#,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*:::::::::::*..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*::::::::::;*..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************.-,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
£...............,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
Y*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,#
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,.
.*************..............................##.#........