manifest.font.content-type.gradle

jar {
    final fileTree = fileTree('src/main/resources')
    final rootDir = fileTree.dir.toPath()
    for (file in fileTree) {
        if (file.isDirectory()) {
            continue
        }
        final name = rootDir.relativize(file.toPath()).toString()
        if (name.length() <= 4) {
            continue
        }
        if (name.charAt(name.length() - 4) != '.') {
            continue
        }
        final fileExtension = name[-3..-1].toLowerCase(Locale.ROOT)
        final contentType
        switch (fileExtension) {
            case 'ttf':
                contentType = 'application/x-font-truetype'
                break
            case 'pfb':
            case 'pfm':
            case 'afm':
            case 'otf':
                contentType = 'application/x-font'
                break
            default:
                contentType = null
                break
        }
        if (contentType) {
            manifest.attributes(['Content-Type': contentType], name)
        }
    }
}