distJarTask.gradle

task distJar(type: Jar, dependsOn: jar) {
    group = DistributionPlugin.DISTRIBUTION_GROUP
    classifier = 'all'
    from {
        configurations.runtime.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    from {
        jar.outputs.files.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    exclude 'META-INF/MANIFEST.MF'
    exclude 'META-INF/*.SF'
    exclude 'META-INF/*.DSA'
    exclude 'META-INF/*.RSA'
    manifest {
        attributes = [
            'Implementation-Title':    '',
            'Implementation-Version':  version,
            'Built-By':                System.getProperty('user.name'),
            'Built-Date':              new Date(),
            'Built-JDK':               System.getProperty('java.version'),
            'Built-Gradle':            gradle.gradleVersion,
            'Main-Class':              mainClassName,
            //'Class-Path': configurations.runtime.collect { it.name }.join(' '),
        ]
    }
}