gistfile1.txt

MAIN SCRIPT:

#!/usr/bin/perl

use strict;
use warnings;

use File::Temp qw(tempfile);

my $commit = shift or die "You have to pass a commit";

# read in the log message
my $log;
{
   my @program = ('git','log','--format=%B','-n',1,$commit);
   my $program = join ' ', @program;
   open my $pfh, "-|", @program
     or die "Can't run '$program': $!";
   $log = do { local $/ = undef; <$pfh> };
   close $pfh
     or die "Can't close program '$program': $!";
}

# git rebase!
{
  local $ENV{EDITOR} = '/Users/mark/bin/picky';
  system("git","rebase","-i","${commit}^")
        == 0 or die "Can't rebase!";
}
system("git reset HEAD~") == 0 or die "Can't git reset";

# do the commits
my @files = `git status  --porcelain`;
foreach my $filename (@files) {
    $filename =~ s/\A[AM ][AM ] // or die "Don't understand: $filename";
    chomp $filename;

    # create a commit message for this
    my ($fh, $tempfilename) = tempfile();
    print $fh "$filename: $log";
    close $fh;

    # commit it
    system("git","add",$filename) == 0 or die "can't git add";
    system("git","commit","-F",$tempfilename);

    unlink $tempfilename;
}

exec("git rebase --continue");


PICKY:

#!/usr/bin/perl

use strict;
use warnings;

use Tie::File;

tie my @array, 'Tie::File', shift or die "Can't tie filename";

foreach (@array) {
    s/pick/edit/ && last;
}