Capture an entire Slack Channel as screenshots

Screenshot.applescript

set epoch to do shell script "perl -e 'print ~~time'"
set dir to "/tmp/" & epoch
do shell script "mkdir " & dir

tell application "Slack" to activate
tell application "System Events"
	set counter to 1
	repeat 1000 times
		delay 1
		
		set activeApp to name of first application process whose frontmost is true
		set winSize to size of window 1 of application process activeApp
		set winPos to position of window 1 of application process activeApp
		do shell script "screencapture -x -R" & item 1 of winPos & "," & item 2 of winPos & "," & item 1 of winSize & "," & item 2 of winSize & " " & dir & "/screenshot-" & counter & ".png"
		
		try
			do shell script "(! cmp -s " & dir & "/screenshot-" & counter & ".png " & dir & "/screenshot-" & (counter - 1) & ".png)"
		on error
			display dialog "Done!"
			return
		end try
		
		set counter to counter + 1
		delay 1
		key code 116
		delay 1
		key code 125
	end repeat
end tell

You'll need to enable the ability for Script Editor to capture the screen and act as an assistive device in order for this to work.