Mathematica Function for Movie Creation with ffmpeg/avconv

ExportMovie.nb

(*
 Mathematica Function for Movie Creation with ffmpeg/avconv
 
 This function enables Mathematica make a long movie file
 with less memory usage.
 
 Copyright (c) 2015 330k
 This software is released under the MIT License.
 http://opensource.org/licenses/mit-license.php
*)
Options[ExportMovie] = {
   "FrameRate" -> 25,
   "VideoCodecOption" -> "-vcodec rawvideo",
   "ExportOptions" -> {}
   };
ExportMovie[outputfilepath_String, 
   expr_, {i_Symbol, imin_: 1, imax_, di_: 1}, OptionsPattern[]] := 
  Module[{stream},
   stream = OpenWrite[
     ToString[
      StringForm[
       "!avconv -y -vcodec ppm -f image2pipe -i - -r `` `` ``"
       , OptionValue["FrameRate"]
       , OptionValue["VideoCodecOption"]
       , outputfilepath
       ]
      ]
     , BinaryFormat -> True];
   Do[
    BinaryWrite[stream, 
     ExportString[expr, "PPM", OptionValue["ExportOptions"]]]
    , {i, imin, imax, di}
    ];
   Close[stream]
   ];
Attributes[ExportMovie] = {HoldAll};
SyntaxInformation[ExportMovie] = {
   "ArgumentsPattern" -> {_, _, {_, _, _., _.}, OptionsPattern[]}
   , "LocalVariables" -> {"Table", {3, 3}}
   };