testian.sqf

[] spawn {
    private _vehicles = "getNumber (_x >> 'ace_cargo_size') > 0" configClasses (configFile >> "CfgVehicles");
    private _startPos = getPos player;

    testian_drawObjects = [];

    {
        private _veh = createVehicle [configName _x, _startPos vectorAdd [0, _forEachIndex * 10, 0], [], 0, "CAN_COLLIDE"];
        testian_drawObjects pushBack _veh;
    } forEach _vehicles;

    testian_drawObjectsEH = addMissionEventHandler ["Draw3D", {
        {
            private _object = _x;
            private _c0 = (boundingBoxReal _x) select 0;
            private _c1 = (boundingBoxReal _x) select 1;

            private _lines = [
                [_c0, [_c1 select 0, _c0 select 1, _c0 select 2]],
                [_c0, [_c0 select 0, _c1 select 1, _c0 select 2]],
                [_c0, [_c0 select 0, _c0 select 1, _c1 select 2]],
                [_c1, [_c0 select 0, _c1 select 1, _c1 select 2]],
                [_c1, [_c1 select 0, _c0 select 1, _c1 select 2]],
                [_c1, [_c1 select 0, _c1 select 1, _c0 select 2]],
                [[_c1 select 0, _c1 select 1, _c0 select 2], [_c1 select 0, _c0 select 1, _c0 select 2]],
                [[_c1 select 0, _c0 select 1, _c1 select 2], [_c0 select 0, _c0 select 1, _c1 select 2]],
                [[_c1 select 0, _c0 select 1, _c0 select 2], [_c1 select 0, _c0 select 1, _c1 select 2]],
                [[_c0 select 0, _c1 select 1, _c1 select 2], [_c0 select 0, _c0 select 1, _c1 select 2]],
                [[_c0 select 0, _c1 select 1, _c1 select 2], [_c0 select 0, _c1 select 1, _c0 select 2]],
                [[_c0 select 0, _c1 select 1, _c0 select 2], [_c1 select 0, _c1 select 1, _c0 select 2]]
            ];

            {
                drawLine3D [
                    _object modelToWorldVisual (_x select 0),
                    _object modelToWorldVisual (_x select 1),
                    [1, 1, 1, 1]
                ];
            } forEach _lines;

            private _volume = ((_c1 select 0) - (_c0 select 0)) * ((_c1 select 1) - (_c0 select 1)) * ((_c1 select 2) - (_c0 select 2));
            drawIcon3D ["", [1, 1, 1, 1], getPos _object, 1, 1, 0, format ["%1 m³", _volume]];
        } forEach testian_drawObjects;
    }];
};