Created
April 14, 2020 20:14
-
-
Save anarsoul/9f0d82d0e81e8a340db5fb120cbc38c3 to your computer and use it in GitHub Desktop.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# Maintainer: Lone_Wolf <lonewolf at xs4all dot nl> | |
# Contributor: Armin K. <krejzi at email dot com> | |
# Contributor: Kristian Klausen <klausenbusk@hotmail.com> | |
# Contributor: Egon Ashrafinia <e.ashrafinia@gmail.com> | |
# Contributor: Tavian Barnes <tavianator@gmail.com> | |
# Contributor: Jan de Groot <jgc@archlinux.org> | |
# Contributor: Andreas Radke <andyrtr@archlinux.org> | |
# Contributor: Thomas Dziedzic < gostrc at gmail > | |
# Contributor: Antti "Tera" Oja <antti.bofh@gmail.com> | |
# Contributor: Diego Jose <diegoxter1006@gmail.com> | |
pkgname=mesa-git | |
pkgdesc="an open-source implementation of the OpenGL specification, git version" | |
pkgver=20.1.0_devel.121864.d52b3e50087 | |
pkgrel=1 | |
arch=('x86_64' 'aarch64') | |
makedepends=('git' 'python-mako' 'xorgproto' | |
'libxml2' 'libx11' 'libvdpau' 'libva' 'elfutils' 'libomxil-bellagio' 'libxrandr' | |
'ocl-icd' 'vulkan-icd-loader' 'libgcrypt' 'wayland' 'wayland-protocols' 'meson' 'ninja') | |
depends=('libdrm' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'libelf' | |
'libomxil-bellagio' 'libunwind' 'libglvnd' 'wayland' 'lm_sensors' 'libclc' 'glslang') | |
optdepends=('opengl-man-pages: for the OpenGL API man pages') | |
provides=(mesa=$pkgver-$pkgrel vulkan-mesa-layer=$pkgver-$pkgrel vulkan-driver opencl- opengl-driver opencl-driver) | |
conflicts=('mesa' 'opencl-mesa' 'vulkan-intel' 'vulkan-radeon' 'vulkan-mesa-layer' 'libva-mesa-driver' 'mesa-vdpau') | |
#options=('!strip') | |
url="https://www.mesa3d.org" | |
license=('custom') | |
source=('mesa::git+https://gitlab.freedesktop.org/mesa/mesa.git#branch=master' | |
'LICENSE' | |
) | |
md5sums=('SKIP' | |
'5c65a0fe315dd347e09b1f2826a1df5a') | |
sha512sums=('SKIP' | |
'25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2') | |
# NINJAFLAGS is an env var used to pass commandline options to ninja | |
# NOTE: It's your responbility to validate the value of $NINJAFLAGS. If unsure, don't set it. | |
pkgver() { | |
cd mesa | |
read -r _ver <VERSION | |
echo ${_ver/-/_}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD) | |
} | |
prepare() { | |
# although removing _build folder in build() function feels more natural, | |
# that interferes with the spirit of makepkg --noextract | |
if [ -d _build ]; then | |
rm -rf _build | |
fi | |
} | |
build() { | |
#CFLAGS="-Og -g3" | |
#CXXFLAGS="-Og -g3" | |
MESON_OPT="-D asm=false --buildtype=release" | |
case "${CARCH}" in | |
armv6h) GALLIUM=",vc4" ;; | |
armv7h) GALLIUM=",etnaviv,kmsro,lima,panfrost,tegra,vc4" ;; | |
aarch64) GALLIUM=",kmsro,lima,panfrost" ;; | |
esac | |
arch-meson mesa _build \ | |
-D b_ndebug=true \ | |
-D platforms=x11,wayland,drm,surfaceless \ | |
-D dri-drivers= \ | |
-D gallium-drivers=swrast${GALLIUM} \ | |
-D vulkan-drivers= \ | |
-D dri3=true \ | |
-D egl=true \ | |
-D gallium-extra-hud=true \ | |
-D gbm=true \ | |
-D gles1=true \ | |
-D gles2=true \ | |
-D glvnd=true \ | |
-D glx=dri \ | |
-D libunwind=false \ | |
-D llvm=false \ | |
-D lmsensors=true \ | |
-D osmesa=gallium \ | |
-D shared-glapi=true \ | |
-D valgrind=false $MESON_OPT | |
meson configure _build | |
ninja $NINJAFLAGS -C _build | |
} | |
package() { | |
DESTDIR="$pkgdir" ninja $NINJAFLAGS -C _build install | |
# indirect rendering | |
ln -s /usr/lib/libGLX_mesa.so.0 ${pkgdir}/usr/lib/libGLX_indirect.so.0 | |
install -Dt "$pkgdir"/usr/share/licenses/$pkgname "$srcdir"/LICENSE | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment