Skip to content

Instantly share code, notes, and snippets.

@AJMartel

AJMartel/mine.ino

Forked from madc/mine.ino
Created Jan 11, 2020
Embed
What would you like to do?
Arduino code for the Goldeneye 007 Remote Mine Prop (http://www.thingiverse.com/make:125687)
#include "pitches.h"
const int pinButton = 2;
const int pinSpeaker = 4;
const int pinLED[] = {3, 5, 6, 9, 10, 11};
boolean running = false;
volatile int mode = 0;
volatile unsigned long button_pressed = 0;
int animation_step = 0;
unsigned long animation_step_time = 0;
const int animation_map[6][6][7] = {
{ // Mode 1: Running Light
{1, 0, 0, 0, 0, 0, 300},
{0, 1, 0, 0, 0, 0, 300},
{0, 0, 1, 0, 0, 0, 300},
{0, 0, 0, 1, 0, 0, 300},
{0, 0, 0, 0, 1, 0, 300},
{0, 0, 0, 0, 0, 1, 300}
},
{ // Mode 2: Inverse Running Light
{0, 0, 0, 0, 0, 1, 300},
{0, 0, 0, 0, 1, 0, 300},
{0, 0, 0, 1, 0, 0, 300},
{0, 0, 1, 0, 0, 0, 300},
{0, 1, 0, 0, 0, 0, 300},
{1, 0, 0, 0, 0, 0, 300}
},
{ // Mode 3: Chasing Light
{1, 0, 0, 1, 0, 0, 150},
{0, 1, 0, 0, 1, 0, 150},
{0, 0, 1, 0, 0, 1, 150},
{1, 0, 0, 1, 0, 0, 150},
{0, 1, 0, 0, 1, 0, 150},
{0, 0, 1, 0, 0, 1, 150}
},
{ // Mode 4: Inverse Double Knight Rider
{1, 0, 0, 1, 0, 0, 150},
{0, 1, 0, 0, 1, 0, 150},
{0, 0, 1, 0, 0, 1, 150},
{0, 0, 1, 0, 0, 1, 150},
{0, 1, 0, 0, 1, 0, 150},
{1, 0, 0, 1, 0, 0, 150}
},
{ // Mode 5: Double Knight Rider
{1, 0, 0, 0, 0, 1, 300},
{0, 1, 0, 0, 1, 0, 300},
{0, 0, 1, 1, 0, 0, 300},
{0, 0, 1, 1, 0, 0, 300},
{0, 1, 0, 0, 1, 0, 300},
{1, 0, 0, 0, 0, 1, 300}
},
{ // Mode 6: FLASH
{0, 0, 0, 0, 0, 0, 600},
{1, 1, 1, 1, 1, 1, 300},
{0, 0, 0, 0, 0, 0, 600},
{1, 1, 1, 1, 1, 1, 300},
{0, 0, 0, 0, 0, 0, 600},
{1, 1, 1, 1, 1, 1, 300}
}
};
int melody[] = {NOTE_C5, NOTE_G4, NOTE_G4, NOTE_A4, NOTE_G4, 0, NOTE_B4, NOTE_C5};
int noteDurations[] = {8, 12, 12, 8, 8, 4, 8, 8};
void setup() {
for(int i=0; i<6; i++) {
pinMode(pinLED[i], OUTPUT);
}
pinMode(pinButton, INPUT);
attachInterrupt(0, changeMode, RISING);
pinMode(pinSpeaker, OUTPUT);
//Startup Sound
turnLEDs(1);
tone(pinSpeaker, NOTE_E5, 1000/8);
delay(160);
tone(pinSpeaker, NOTE_A5, 1000/8);
delay(160);
turnLEDs(0);
}
void loop() {
if(running) {
executeMode();
} else {
if(!digitalRead(pinLED[mode-1])) {
turnLEDs(0);
digitalWrite(pinLED[mode-1], HIGH);
}
if(button_pressed > 0 && mode > 0 && millis()-button_pressed > 1000) {
running = true;
}
}
}
// Interrupt 0: Changing Mode when button is pressed.
void changeMode() {
if(millis()-button_pressed > 300) {
if(running) {
mode = 0;
} else if(mode == 6) {
mode = 1;
tone(pinSpeaker, NOTE_E5, 1000/8);
} else {
mode++;
tone(pinSpeaker, NOTE_E5, 1000/8);
}
button_pressed = millis();
}
}
// Process the animation
void executeMode() {
if(mode == 0) {
running = false;
animation_step = 0;
explode();
} else {
if(millis()-animation_step_time >= animation_map[mode-1][animation_step][6]) {
tone(pinSpeaker, NOTE_A5, animation_map[mode-1][animation_step][6]/3);
for(int i=0; i<6; i++) {
digitalWrite(pinLED[i], animation_map[mode-1][animation_step][i]);
}
if(animation_step == 5) {
animation_step = 0;
} else {
animation_step++;
}
animation_step_time = millis();
}
}
}
// LED animation and sound for "explosion"
void explode() {
turnLEDs(1);
tone(pinSpeaker, NOTE_A5, 500);
delay(500);
unsigned long time = millis();
while(millis() - time <= 300) {
tone(pinSpeaker, (millis() - time)/2);
}
noise(100, 100);
time = millis();
while(millis() - time <= 300) {
tone(pinSpeaker, 300-(millis() - time)/2);
}
noise(100, 1500);
turnLEDs(0);
for (int thisNote = 0; thisNote < 8; thisNote++) {
int noteDuration = 1000/noteDurations[thisNote];
tone(pinSpeaker, melody[thisNote], noteDuration);
int pauseBetweenNotes = noteDuration * 1.30;
delay(pauseBetweenNotes);
}
}
// Generating white noise on the speaker
void noise(int freq, int duration) {
int low = freq - 300;
int high = freq + 300;
unsigned long time = millis();
while(millis() - time <= duration) {
int rand = random(low, high) - duration/100;
tone(pinSpeaker, rand);
}
}
// Turning all LEDs on(1) or off(0).
void turnLEDs(int onoff) {
for(int i=0; i<6; i++) {
digitalWrite(pinLED[i], onoff);
}
}
// This note table was originally written by Brett Hagman
// http://arduino.cc/en/Tutorial/tone
#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment