Utilises the enhanced 'clickdrag.swift' that allows all inputs to be negative. Also supports capturing bezel drop-shadow.

Start Screen Recording.scpt

set theProcessName to "Simulator"
set theWindowNumber to 1

-- set this to 'true' to increase the captured screen region
-- to include device bezel drop-shadow
set includeDropshadowRegion to false

tell application "System Events"
	tell process theProcessName
		activate
		tell window theWindowNumber
			set thePosition to position
			set theSize to size
		end tell
	end tell
end tell

on roundedabs(num)
	if num < 0 then return round (num * -1)
	return round (num)
end roundedabs

tell application "QuickTime Player"
	activate
	new screen recording
	delay 1
	tell application "System Events" to key code 49
	delay 1
	set x to item 1 of thePosition
	set y to item 2 of thePosition
	set dx to item 1 of theSize
	set dy to item 2 of theSize
	
	if includeDropshadowRegion then
		-- compensate for dropshadow by scaling the
		-- recorded region by known percentages
		set x to x - dx * 0.1
		set y to y - dy * 0.038
		set dx to dx * (1 + 0.2)
		set dy to dy * (1 + 0.038 + 0.065)
	end if
	
	do shell script "/Applications/clickdrag.swift -x " & my roundedabs(x) & " -y " & my roundedabs(y) & " -dx " & my roundedabs(dx) & " -dy " & my roundedabs(dy) & " -negx " & (x < 0) & " -negy " & (y < 0) & " -negdx " & (dx < 0) & " -negdy " & (dy < 0)
end tell