dimemas-5.4.2.ebuild

# Copyright 2019-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( pypy3 python3_{8..10} )

inherit autotools java-pkg-opt-2 python-any-r1

DESCRIPTION="High-abstracted network simulator for message-passing programs."
HOMEPAGE="https://github.com/bsc-performance-tools/dimemas"
SRC_URI="https://github.com/bsc-performance-tools/dimemas/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"

IUSE="dyninst idle-accounting irecv-startup libunwind mrnet original-links peruse sampling venus wait-logical-recv"

CDEPEND="
	dev-libs/boost
	sys-libs/zlib

"
DEPEND="
	${CDEPEND}
	${PYTHON_DEPS}
	java? ( virtual/jdk:1.8 )
"
RDEPEND="
	${CDEPEND}
	java? ( virtual/jre:1.8 )
"
BDEPEND="
	sys-devel/flex
	virtual/yacc
"

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	local myconf=(
		--with-boost="${EPREFIX}/usr"
		--with-boost-libdir="${EPREFIX}/usr/$(get_libdir)"

		$(use_enable idle-accounting)
		$(use_enable irecv-startup)
		$(use_enable original-links)
		$(use_enable wait-logical-recv)
	)

	use venus && myconf+=( "--enable-venus" )

	econf "${myconf[@]}"
}

src_install() {
	default

	find "${ED}" -name '*.la' -delete || die
}