Add "ignored" status to statusline

parse_ignore.vim

" As an example, put it in the statusline (you should not do this here, just put the %{} in your config):
let &statusline = substitute(&statusline, '%f', '%f%{get(b:,"ignore_status","")}', '')

"
" get(b:, "ignore_status", "") -> Get the key "ignore_status" from the
" dictionary b: (all buffer-local variables), defaulting to ""
"

augroup IgnoreStatus
  autocmd!

  autocmd BufRead * call s:UpdateIgnoreStatus()
augroup END

function! s:UpdateIgnoreStatus() abort
  " Note: only checks for .gitignore
  let ignore_file = findfile('.gitignore', '.;')

  if ignore_file == '' || !filereadable(ignore_file)
    return
  endif

  for glob in readfile(ignore_file)
    if glob !~ '^[^#]'
      " It's a comment or blank line
      continue
    endif

    " Some git patterns start with /
    let glob = substitute(glob, '^/', '', '')

    if expand('%') =~ glob2regpat(glob)
      let b:ignore_status = " (ignored)"
      return
    endif
  endfor

  let b:ignore_status = ""
endfunction