Automatically update zig binary to zig x86_64 master.

ZIG_UPDATE.bat

@ECHO OFF
REM Automatic Zig Download and Install Script
REM Add the variable (as a variable) %ZIGPATH% to user path for usage.
REM Requires jq to be installed.

SET zigurl=https://ziglang.org/download/index.json
SET zigjson=.\zigmaster.json

ECHO Fetching Zig Master .json
curl -o %zigjson% %zigurl%
jq -r .master."""x86_64-windows""".tarball %zigjson% >tempfile
SET /p updateurl=<tempfile
jq -r .master."""x86_64-windows""".shasum %zigjson% >tempfile
SET /p updatesha=<tempfile

ECHO FETCHING
ECHO URL: %updateurl%
ECHO SHA: %updatesha%

curl -OJ "%updateurl%"
FOR %%i IN (%updateurl:/= %) DO SET updatefile=%%i
SET updatefolder=%updatefile:~0,-4%

ECHO DOWNLOADED: %updatefile%

ECHO UNZIPPING
tar -xf "%updatefile%"

ECHO OLD ZIGPATH: %ZIGPATH%
SET oldzig=%ZIGPATH%
SET newzig="%CD%\%updatefolder%"
ECHO NEW ZIGPATH: %newzig%
SETX ZIGPATH %newzig%

ECHO Cleaning Up
ECHO Delete Old Zig Installation:
IF EXIST %oldzig% RMDIR /S %oldzig%
DEL "%updatefile%"
DEL %zigjson%
DEL tempfile

PAUSE

Note it doesn't check the currently installed version of Zig. It just downloads master always.