PKGBUILD for tilemill-git

PKGBUILD

# Contributor: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Alexander Minges <alexander.minges@gmail.com>
# Maintainer: Jonas Heinrich <onny@project-insanity.org>

pkgname=tilemill-git
_pkgname=tilemill
pkgver=v0.10.1.292.g021d71d
pkgrel=1
pkgdesc="A modern map design studio"
arch=(any)
url="https://github.com/mapbox/tilemill"
license=(BSD)
makedepends=('git')
depends=('nodejs' 'mapnik' 'webkitgtk2' 'protobuf') # desktop-file-utils
source=('git+https://github.com/mapbox/tilemill.git'
        'tilemill.png'
        'tilemill.desktop'
        'tilemill.install')
sha1sums=('SKIP'
          '350bbce4e2a3a338123e919f050c418d317a7862'
          '9aced645fcc1407e7a0cb864a48501e3048a4c37'
          'f011df5ca2f0597ddd51c4d5f1b365caa0c7c847')

pkgver() {
  cd "$SRCDEST/${_pkgname}"
  git describe --always | sed 's|-|.|g'
}

package() {
  cd "$srcdir/${_pkgname}"

  mkdir -p "$pkgdir/usr"
  npm install -d -g --prefix "$pkgdir/usr"

  # icon and .desktop files
  install -Dm644 $srcdir/tilemill.png "$pkgdir/usr/share/pixmaps/tilemill.png"
  install -Dm644 $srcdir/tilemill.desktop "$pkgdir/usr/share/applications/tilemill.desktop"
  install -Dm644 $pkgdir/usr/lib/node_modules/tilemill/LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # don't install files already owned by npm
  rm -rf "$pkgdir/usr/lib/node_modules/npm/"
  rm "$pkgdir/usr/bin/npm"
}
# vim:set ts=2 sw=2 et: