htmail-view-git

PKGBUILD

# Maintainer: Beini <bane at iki dot fi>
# Contributor: sergej <sergej+arch at p5n.pp dot ru>
pkgname=htmail-view-git
_pkgname="${pkgname%-git}"
pkgver=v0.6.r3.59e04aa
pkgrel=1
pkgdesc="Single web page renderer based on WebKit2"
arch=('any')
url="https://github.com/liske/htmail-view"
license=('GPL2')
depends=('perl-browser-open'
         'perl-uri'
         'perl-glib-object-introspection'
         'perl-mail-mboxparser'
         'gtk3'
         'webkit2gtk')
makedepends=('git')
optdepends=('wmctrl: Focus handling')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/liske/$_pkgname.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

prepare() {
  cd "$srcdir/$_pkgname"
  sed -i 's;etc/Muttrc\.d;usr/share/doc/htmail-view;g' Makefile
}

package() {
  cd "$srcdir/$_pkgname"
  make DESTDIR="$pkgdir/" install
  for _page in htmail-decode.1 htmail-view.1
  do
    install -m 644 -D "man/$_page" "$pkgdir/usr/share/man/man1/$_page"
  done
}

# vim:set ts=2 sw=2 et: