Trying to unquote a map from a macro does not compile

keyword_lists.ex

defmodule Test do
  defmacro __using__(opts) do
    quote do
      import unquote(__MODULE__), only: [map_test: 0]
    end
  end

  #works as expected
  defmacro map_test do
    bar = [foo: "bar"]
    quote do
      def foo do
        unquote(bar)
      end
    end
  end
end

maps.ex

defmodule Test do
  defmacro __using__(opts) do
    quote do
      import unquote(__MODULE__), only: [map_test: 0]
    end
  end

  # This fails to compile with 
  # Compiled lib/test.ex
  # ** (CompileError) test/test_test.exs: invalid quoted expression: %{foo: "bar"}
  #    test/test_test.exs:5: (module)
  defmacro map_test do
    bar = %{ :foo => "bar" }
    quote do
      def foo do
        unquote(bar)
      end
    end
  end
end

test_test.ex

defmodule TestTest do
  use ExUnit.Case

  defmodule TestHelper do
    use Test
    map_test
  end

  test "content is properly inlined" do
    IO.inspect TestHelper.foo
  end
end

The solution is

defmodule Test do
  defmacro map_test do
    bar = %{ :foo => "bar" } |> Macro.escape
    quote do
      def foo do
        unquote(bar)
      end
    end
  end
end

See http://elixir-lang.org/getting-started/meta/quote-and-unquote.html#escaping for more infos