lantern pkgbuild, client UI can be found under http://0.0.0.0:16823

PKGBUILD

# Maintainer:  Marcin (CTRL) Wieczorek <marcin@marcin.co>
# Contributor: neo.shadowsocks<neo.shadowsocks AT gmx.com>
# Contributor: Kars Wang <jaklsy g-mail>

pkgname=lantern
pkgver=2.2.4
pkgrel=1
pkgdesc='Lantern is a free desktop application that delivers fast, reliable and secure access to the open Internet. (Stable Channel)'
arch=('i686' 'x86_64')
url='https://getlantern.org'
license=('Apache')
depends=('xcb-util' 'xdg-utils')
makedepends=('go>=1.6' 'make' 'npm')
conflicts=('lantern-bin' 'lantern-headless' 'lantern-headless-git')
options=('!emptydirs' '!strip' '!docs')
install=$pkgname.install
source=("https://github.com/getlantern/lantern/archive/${pkgver}.tar.gz"
        'lantern.service'
        'git-update-index.patch')

sha1sums=('26fa91dfe92f90c677aa8cc0f410486dffed9e43'
          'da705ba2fa3608a17258009b933e8bb58b3172a2'
          '0949f76ee7d695156c0a85565ce516a7f3637b2a')

prepare() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    patch -p1 < ../git-update-index.patch
    
    # install gulp
    mkdir -p ${srcdir}/gulp
    cd ${srcdir}/gulp
    npm i -g --prefix ./ gulp
}

build() {
    export PATH=${PATH}:${srcdir}/gulp/bin
    cd "${srcdir}/${pkgname}-${pkgver}"
    VERSION=${pkgver} HEADLESS=true make lantern
}

package() {
    install -Dm755 "${srcdir}/${pkgname}-${pkgver}/lantern"    "${pkgdir}/usr/bin/lantern"
    install -Dm644 "${srcdir}/lantern.service"                  "${pkgdir}/usr/lib/systemd/user/lantern.service"
    install -Dm644 ${srcdir}/${pkgname}-${pkgver}/installer-resources/linux/lantern.desktop ${pkgdir}/usr/share/applications/lantern.desktop
    install -Dm644 ${srcdir}/${pkgname}-${pkgver}/installer-resources/linux/deb-copyright ${pkgdir}/usr/share/doc/lantern/copyright
    install -Dm644 ${srcdir}/${pkgname}-${pkgver}/installer-resources/linux/icon128x128on.png ${pkgdir}/usr/share/icons/hicolor/128x128/apps/lantern.png
}