BoXOR Prototype (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title BoXOR Prototype
author Carnun Marcus-Page
homepage www.puzzlescript.net

========
OBJECTS
========

Background
white
00000
00000
00000
00000
00000

OuterWall
black
00000
00000
00000
00000
00000

Wall
black darkgray
00000
00000
00100
00000
00000

UnWall
black
.....
.....
.....
.....
.....

UnPhaser
black
.....
.....
.....
.....
.....

(alts for dev purposes)
(UnWall
lightgray white
00000
00000
00100
00000
00000

UnPhaser
white lightgray
10001
01010
00100
01010
10001)

Block
black darkgray
10101
01010
10101
01010
10101

PhasedBlock
white gray darkgray
01010
10101
01210
10101
01010

Exit
grey black white
00000
01110
01210
01110
00000

Player
black
.....
.000.
.000.
.000.
.0.0.

=======
LEGEND
=======

. = Background
# = OuterWall
E = Exit
@ = Player

W = Wall and UnWall
U = Unwall
X = UnPhaser
B = Block
Z = PhasedBlock and UnWall

Pushable = Block or PhasedBlock

=======
SOUNDS
=======

SFX0 30483704
SFX1 81093304
Pushable MOVE 36772507

================
COLLISIONLAYERS
================

Background,
Exit, UnWall, UnPhaser,
PhasedBlock,
Player, Block, Wall, OuterWall

======
RULES
======

rigid [ > Player | Block ] -> [ > Player | > Block ]
+ rigid [ moving Pushable | Pushable ] -> [ moving Pushable | moving Pushable ]
+ rigid [ > Pushable | Exit ] -> [ Pushable | Exit ]

[ > Player | Wall ] -> [ Player | Wall ] SFX0

[ > Pushable | Wall ] -> [ | PhasedBlock UnWall ]
[ > Block | Exit ] -> [ Block | Exit ]

[ > PhasedBlock | OuterWall ] -> [ PhasedBlock | OuterWall ]

late [ Block UnWall ] -> [ PhasedBlock UnWall ]
late [ PhasedBlock UnPhaser ] -> [ Block UnPhaser ]
late [ NO PhasedBlock UnWall ] -> [ Wall UnWall ]

==============
WINCONDITIONS
==============

ALL Player ON Exit
SOME Player

=======
LEVELS
=======

message Hello.
#########
#.....w.#
#.b.@.w.e
#.....w.#
#########

message Well...
###e###
###w###
###w###
##...##
#.b...#
#..b..#
#.....#
##.@.##
#######

message You're a clever one, aren't you?
############
#wwwwwx..###
#wwwwwxb..##
#wwwwwx.b..#
ewwwwwx..b.@
#wwwwwx.b..#
#wwwwwxb..##
#wwwwwx..###
############

message But how clever?
########
###.b.##
#..b...#
#.b....#
#@.##b.#
###wwx.#
##ewwx.#
########

message We'll see. Won't we?
#.@.#
#...#
#.b.#
#.b.#
#...#
#.b.#
##w##
##w##
##e##