checkpoint_1_shaderplace.glsl

#ifdef GL_ES
precision mediump float;
#endif

uniform vec2 u_resolution;
uniform float u_time;
uniform float u_vol;
// http://www.iquilezles.org/www/articles/palettes/palettes.htm 
// to see this function graphed out go to: https://www.desmos.com/calculator/rz7abjujdj
vec3 cosPalette( float t , vec3 brightness, vec3 contrast, vec3 osc, vec3 phase)
{

    return brightness + contrast*cos( 6.28318*(osc*t+phase) );
}

void main() {
    
    vec2 pos = ((gl_FragCoord.xy/u_resolution) - 0.5)*2.0; // origin is in center
    
    // who remembers SOH CAH TOA ?
    // tan, given an angle will return the ratio
    // so if we only have the ratio of position
    // we use atan to get the angle
    float angle = atan(pos.y,pos.x);
    
    float r = sin(angle + u_time); 
    // sin returns a number from -1 to 1, and colors are from 0 to 1, so thats 
    // why you only see red on the screen half the time. the angle goes around
    // the screen, adding time moves it clockwise
    
	float ringFrequency = 5.; // making this number bigger will increase frequency
	float g = cos(length(pos*ringFrequency) - u_time); 
	// the distance (aka length) from the center put in a cos, time moves the 
	// circles in. 
	
	float b = cos(angle+ cos(length(pos*ringFrequency *3.))); 
	// this combines what we learned in the red and green channels
	// angle is going through a cos and so is the length, so we see the 
	// blue channel oscillating in both dimensions the polar coordinates give us
	    // please play around with these numbers to get a better palette
    vec3 brightness = vec3(0.8);
    vec3 contrast = vec3(0.2);
    vec3 osc = vec3(r);
    vec3 phase = vec3(g, cos(u_time/23.), sin(u_time/31.));
    
    vec3 color = cosPalette(b, brightness, contrast, osc, phase);

    
    gl_FragColor = vec4(color,1.);
    
}