imagescan-3.61.0.ebuild

imagescan-3.61.0.ebuild

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

inherit autotools desktop

DESCRIPTION="EPSON Image Scan v3 for Linux"
HOMEPAGE="https://gitlab.com/utsushi/imagescan"
SRC_URI="https://gitlab.com/utsushi/imagescan/-/archive/${PV}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"

IUSE="imagemagick test"

BDEPEND="
	dev-cpp/gtkmm:2.4
	virtual/pkgconfig
	imagemagick? (
		virtual/imagemagick-tools
	)
"
DEPEND="
	imagemagick? ( !>=media-gfx/imagemagick-7.0.9.8 )
"
RDEPEND="${DEPEND}
	media-gfx/iscan-data
	media-gfx/sane-backends
"

src_prepare() {
	! use test && sed -i 's/SUBDIRS += tests//' Makefile.am ||
		die "Disabling tests was less than successful."

	sed -i 's/-Werror//g' configure.ac ||
		die "Disabling -Werror was less than successful."

	eautoreconf

	default
}

src_configure() {
	local myeconfargs=(
		--disable-static
		--with-boost-libdir="${EPREFIX}"/usr/"$(get_libdir)"
		--with-gtkmm
		--with-jpeg
		$(usex imagemagick '--with-magick --with-magick-pp' '--without-magick --without-magick-pp')
		--with-sane-confdir="${EPREFIX}"/etc/sane.d
		--with-tiff
		--with-udev-confdir="/lib/udev/rules.d"
		--without-included-boost
	)

	econf "${myeconfargs[@]}"
}

src_install() {
	insinto /lib/udev/rules.d
	doins "${S}/drivers/esci/utsushi-esci.rules"

	make_desktop_entry utsushi "Imagescan" scanner

	default
}