llvm-mesa

PKGBUILD

pkgname=('llvm-mesa')
pkgver=7.0.0svn_r164147
pkgrel=1
_prefix="/usr/lib/llvm-mesa"
arch=('i686' 'x86_64')
url="http://llvm.org/"
license=('custom:University of Illinois/NCSA Open Source License')
makedepends=('cmake' 'libffi' 'python2' 'python-sphinx' 'libedit' 'swig')
makedepends_x86_64=('gcc-multilib')
options=('staticlibs')
source=(
	"llvm::git+https://git.llvm.org/git/llvm.git/")
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/llvm"

    # This will almost match the output of `llvm-config --version` when the
    # LLVM_APPEND_VC_REV cmake flag is turned on. The only difference is
    # dash being replaced with underscore because of Pacman requirements.
    echo $(awk -F 'MAJOR |MINOR |PATCH |SUFFIX |)' \
            'BEGIN { ORS="." ; i=0 } \
             /set\(LLVM_VERSION_/ { print $2 ; i++ ; if (i==2) ORS="" } \
             END { print "\n" }' \
        CMakeLists.txt)_$(printf "r%s" "$(git rev-list --count HEAD)")
}

prepare() {
  cd "$srcdir/llvm"
  mkdir -p build

  #mv "$srcdir/compiler-rt-$pkgver.src" projects/compiler-rt
}

build() {
  cd "$srcdir/llvm/build"

  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="${_prefix}" \
    -DLLVM_BUILD_LLVM_DYLIB=ON \
    -DLLVM_LINK_LLVM_DYLIB=ON \
    -DLLVM_INSTALL_UTILS=OFF \
    -DLLVM_ENABLE_RTTI=OFF \
    -DLLVM_ENABLE_FFI=OFF \
    -DLLVM_BUILD_TESTS=OFF \
    -DLLVM_BUILD_UTILS=OFF \
    -DLLVM_ENABLE_DOXYGEN=OFF \
    -DCLANG_INSTALL_SCANBUILD=OFF \
    -DCLANG_INSTALL_SCANVIEW=OFF \
    -DLLVM_BINUTILS_INCDIR=/usr/include \
    -DLLVM_ENABLE_OCAMLDOC=OFF \
    -DLLVM_INCLUDE_DOCS=OFF \
    -DLLVM_INCLUDE_EXAMPLES=OFF \
    -DLLVM_INCLUDE_GO_TESTS=OFF \
    -DLLVM_INCLUDE_TESTS=OFF \
    -DLLVM_TARGETS_TO_BUILD=AMDGPU \
    -DLLVM_INCLUDE_UTILS=OFF \
    -DLLVM_ENABLE_TERMINFO=OFF \
    -DLLVM_ENABLE_ZLIB=OFF \
    -DLLVM_DYLIB_SYMBOL_VERSIONING=ON \
    ..

    #-DFFI_INCLUDE_DIR=$(pkg-config --variable=includedir libffi) \

    make

}


package() {
  cd "$srcdir/llvm/"

  make -C build DESTDIR="$pkgdir" install

  install -Dm644 LICENSE.TXT "${pkgdir}${_prefix}/share/licenses/llvm/LICENSE"

  # add symbolic links in /usr/bin
  mkdir -p "$pkgdir/usr/bin"
  cd "${pkgdir}${_prefix}"/bin
  for f in *; do
    ln -s "${_prefix}/bin/$f" "$pkgdir/usr/bin/${f%-mesa}-mesa"
  done
}

# vim:set ts=2 sw=2 et: