Bazel fuzzy finder ( fzf ) with bat preview

bzqfzf.fish

# Example: vim (bzqfzf //...)

# Description: Fish functions (should be easily converted to zsh) for Basel fuzzy search.

# Requirements:
# bazel
# brew install fzf
# brew install bat

# Note: Put each function to separate `.fish` file.

# functions/bzqfzf.fish

function bzqfzf --description 'Fuzzy finder with preview for Bazel query'
    # Perform Bazel query and pass the results to fzf with custom preview function and key binding
    bazel query $argv | fzf --preview 'bat_preview_for_bazel {}' --bind 'enter:become bazel_file_from_target {}'
end

# functions/bazel_file_from_target.fish

function bazel_file_from_target
    set bazel_target "$argv[1]"
    set bazel_output (bazel query $bazel_target --noshow_progress --output=build | head -1 | sed -e "s/^#[[:space:]]//")
    set bazel_file (echo "$bazel_output" | cut -d: -f1)
    echo "$bazel_file"
end

# functions/bat_preview_for_bazel.fish

function bat_preview_for_bazel
    set bazel_target "$argv[1]"
    set bazel_output (bazel query $bazel_target --noshow_progress --output=build | head -1 | sed -e "s/^#[[:space:]]//")
    set bazel_file (echo "$bazel_output" | cut -d: -f1)
    set line (echo "$bazel_output" | cut -d: -f2)
    bat --style=numbers --color=always --line-range $line: "$bazel_file"
end