Search current folder using Everything

SearchEverything.ahk

#NoTrayIcon
#SingleInstance Force

MyUsername := "Onurtag"           ;Go to your %userprofile% and change this to the title of that window. Keep the quotes.
MyRecycleBin := "Recycle Bin"       ;Go to your Recycle Bin and change this to the title of that window. Keep the quotes.
MyThisPC := "This PC"               ;Go to your This PC and change this to the title of that window. Keep the quotes.

;You can delete below blocks if you don't want the features.

;BLOCK 1 - DESKTOP
#IfWinActive, ahk_class Progman
^F::
    RunPath := "-p ""%UserProfile%""" . "\" . "Desktop" . "\"
    Run, C:\Program Files\Everything\Everything.exe %RunPath%
    Return

;BLOCK 2 - TASKBAR
#IfWinActive, ahk_class Shell_TrayWnd
^F::
    Run, C:\Program Files\Everything\Everything.exe
    Return

;BLOCK 3 - EXPLORER WINDOW
#IfWinActive, ahk_class CabinetWClass
^F::
    ControlGetText, RunPath, ToolbarWindow323, A
    RunPath := SubStr(RunPath, 10)
    isnotauserfolder := ":\"
    IfNotInString, RunPath, %isnotauserfolder%
    {
        if (RunPath == MyThisPC) 
        {
            RunPath := ""
        } else if (RunPath == MyUsername) {
            RunPath := "-p ""%UserProfile%"""
        } else if (RunPath == MyRecycleBin) {
            RunPath := "-s ""\$RECYCLE.BIN """
        } else {
            RunPath := "-p ""%UserProfile%""" . "\" . RunPath . "\"
        }
    } else {
        RunPath := "-p """ . RunPath . """"
    }
    Run, C:\Program Files\Everything\Everything.exe %RunPath%
    Return