Latest mutter build for 3.24 branch with reverting https://git.gnome.org/browse/mutter/commit/?h=gnome-3-24&id=383ba566bd7c2a76d0856015a66e47caedef06b6

PKGBUILD

pkgname=mutter
pkgver=3.26.1
pkgrel=1
pkgdesc="A window manager for GNOME"
url="https://git.gnome.org/browse/mutter"
arch=(i686 x86_64)
license=(GPL)
depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
         libcanberra startup-notification zenity libsm gnome-desktop upower
         libxkbcommon-x11 gnome-settings-daemon libgudev libinput)
makedepends=(intltool gobject-introspection git gnome-common)
groups=(gnome)
options=(!emptydirs)
source=("git+https://git.gnome.org/browse/mutter#branch=gnome-3-26")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git revert -n 383ba566bd7c2a76d0856015a66e47caedef06b6 


  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib/$pkgname --disable-static \
      --disable-schemas-compile --enable-compile-warnings=minimum \
      --enable-gtk-doc --enable-egl-device --enable-remote-desktop

  #https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
      -i {.,cogl,clutter}/libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

I needed to change git revert -n 383ba566bd7c2a76d0856015a66e47caedef06b6 line to git revert -n --strategy=recursive -Xtheirs 383ba566bd7c2a76d0856015a66e47caedef06b6 as the former one was causing merge conflicts.