gr-iio.patch

diff --unified --recursive --text gr-iio/CMakeLists.txt gr-iio.new/CMakeLists.txt
--- gr-iio/CMakeLists.txt	2019-12-23 22:52:55.553601264 +0100
+++ gr-iio.new/CMakeLists.txt	2019-12-23 23:09:32.061566013 +0100
@@ -83,7 +83,7 @@
 ########################################################################
 # Find packages
 ########################################################################
-find_package(Gnuradio "3.8" REQUIRED)
+find_package(Gnuradio "3.8" REQUIRED COMPONENTS blocks analog volk pmt filter fft)
 include(GrVersion)
 include(GrPlatform) #define LIB_SUFFIX
 
@@ -109,14 +109,16 @@
 # components required to the list of GR_REQUIRED_COMPONENTS (in all
 # caps such as FILTER or FFT) and change the version to the minimum
 # API compatible version required.
-find_package(Gnuradio COMPONENTS blocks analog volk pmt filter fft)
-find_package(Gnuradio PATHS "c:/Program Files/gnuradio/lib/cmake/gnuradio" REQUIRED)
+#find_package(Gnuradio COMPONENTS blocks analog volk pmt filter fft)
+#find_package(Gnuradio PATHS "c:/Program Files/gnuradio/lib/cmake/gnuradio" REQUIRED)
 
 find_library(IIO_LIBRARIES iio)
 find_path(IIO_INCLUDE_DIRS iio.h)
 find_library(AD9361_LIBRARIES ad9361)
 find_path(AD9361_INCLUDE_DIRS ad9361.h)
 
+add_definitions(-DBOOST_CHRONO_HEADER_ONLY)
+
 ########################################################################
 # On Apple only, set install name and use rpath correctly, if not already set
 ########################################################################

PKGBUILD

#Maintainer: Kyle Keen <keenerd@gmail.com?>
pkgname=gnuradio-iio-git
_gitname=gr-iio
pkgver=20190823 
pkgrel=1
pkgdesc="IIO blocks for GNU Radio"
url="https://github.com/analogdevicesinc/gr-iio"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('libad9361-iio')
makedepends=('git' 'cmake' 'boost' 'swig')
provides=('gnuradio-iio')
conflicts=('gnuradio-iio')
source=("git+https://github.com/analogdevicesinc/gr-iio.git#branch=upgrade-3.8"
       "gr-iio.patch")
sha1sums=('SKIP'
          'e84a2d1903312b3b155745765574fe82514ffc66')

pkgver() {
  cd "$_gitname"
  git show -s --format="%ci" HEAD | sed -e 's/-//g' -e 's/ .*//'
}

prepare() {
    cd $_gitname
    patch --forward --strip=1 --input="${srcdir}/gr-iio.patch"
}

build() {
  cd "$_gitname"
  mkdir -p build
  cd build
  export SWIG_FEATURES=-I/usr/include/gnuradio/swig/
  cmake \
    -DPYTHON_EXECUTABLE=$(which python3) \
    -DPYTHON_INCLUDE_DIR=$(echo /usr/include/python3*) \
    -DPYTHON_LIBRARY=$(echo /usr/lib/libpython3.*.so) \
    -DPC_GNURADIO_RUNTIME_VERSION=3.8.0 \
    -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev ../
  make
}

package() {
  cd "$_gitname/build"
  make DESTDIR="${pkgdir}" install
}